恢复Zsh终端（OS X Lion）

OS X Lion具有“恢复”功能，即，当您重新打开应用程序时，它将恢复所有窗口及其内容。这同样适用于Terminal。但是，如果您使用Zsh而不是Bash，它不会还原打开的目录。我怎样才能解决这个问题？

更新：由于注释中提到的原因，这并不完全正确。使用下面的答案。感谢@ChrisPage付出了更多努力:)

答案可以通过反向工程找到bash如何在其中进行/etc/bashrc。我从网上尝试了许多方法，但苹果公司的方法似乎效果最好（见图）。

在您.zshrc添加以下内容

# Set Apple Terminal.app resume directory
if [[ $TERM_PROGRAM == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]] {
  function chpwd {
    local SEARCH=' '
    local REPLACE='%20'
    local PWD_URL="file://$HOSTNAME${PWD//$SEARCH/$REPLACE}"
    printf '\e]7;%s\a' "$PWD_URL"
  }

  chpwd
}

恢复愉快。

为了澄清起见，此答案与OS X Lion的Terminal.app首选项中的神秘消息有关：

**程序使用转义序列将当前工作目录通知终端。您可能需要配置外壳程序或其他程序才能启用此行为。*

当您将zsh用作shell时，此答案有效。苹果已经实施了bash的终端恢复。

这是我对zsh的/ etc / bashrc的改编。我已包括所有需要它的URL字符的百分比编码，如果您希望它与所有有效的文件名和目录名一起使用，则这很重要。

这将注册一个precmd挂钩，该挂钩允许在其他脚本和配置文件中注册多个功能。

2019年3月更新：设置LC_ALL为空，因此不会覆盖LC_CTYPE。用于precmd在每个提示符下更新工作目录，而不是在每次chpwd更改时都进行更新-命令管道可能会临时更改它，并且终端不应显示这些目录。同样，如果在上一个命令中更改了终端状态，则每个提示都将更新终端状态可能会有帮助。使用printf -v明确写入该变量，而不是使用子shell语法。

# Tell the terminal about the working directory whenever it changes.

if [[ "$TERM_PROGRAM" == "Apple_Terminal" ]] && [[ -z "$INSIDE_EMACS" ]]; then

    update_terminal_cwd() {
        # Identify the directory using a "file:" scheme URL, including
        # the host name to disambiguate local vs. remote paths.

        # Percent-encode the pathname.
        local url_path=''
        {
            # Use LC_CTYPE=C to process text byte-by-byte. Ensure that
            # LC_ALL isn't set, so it doesn't interfere.
            local i ch hexch LC_CTYPE=C LC_ALL=
            for ((i = 1; i <= ${#PWD}; ++i)); do
                ch="$PWD[i]"
                if [[ "$ch" =~ [/._~A-Za-z0-9-] ]]; then
                    url_path+="$ch"
                else
                    printf -v hexch "%02X" "'$ch"
                    url_path+="%$hexch"
                fi
            done
        }

        printf '\e]7;%s\a' "file://$HOST$url_path"
    }

    # Register the function so it is called at each prompt.
    autoload add-zsh-hook
    add-zsh-hook precmd update_terminal_cwd
fi