我如何知道哪个“ explorer.exe”进程是主要进程？

我有一个批处理文件，它更改了一些注册表文件，然后重新启动explorer.exe，以便它们生效。我正在使用命令

taskkill /f /im explorer.exe
explorer.exe

当然，这会杀死所有 explorer.exe进程，包括我打开的explorer窗口。（显然，我正在使用的选项Launch folder windows in a separate process。）

我有什么方法可以确定explorer.exe的哪个实例是主要实例，然后杀死它？

基于窗口标题的方法

@ techie007建议杀死explorer.exewith窗口标题N/A。

命令

for /f "tokens=2,10" %%p in ('tasklist /nh /v /fi "imagename eq explorer.exe"') do if "%%q"=="N/A" taskkill /f /pid %%p

怎么运行的

• tasklist /nh /v /fi "imagename eq explorer.exe"详细列出所有具有映像名称的进程explorer.exe。

• for /f "tokens=2,10" %%p in ('COMMAND1') do COMMAND2

  执行COMMAND1。对于输出的每一行，它设置变量%%p和%%q所述第二和第十“令牌”（由空格分隔）和执行COMMAND2。

  对于taskkill /v，%%p 现在保存PID和%%q窗口标题（的开头）。

• if "%%q"=="N/A" taskkill /f /pid %%p检查窗口标题是否为N/A。

  如果是这样，它将通过终止该过程taskkill。

基于内存使用的方法

@Syntech指出，这对于Windows资源管理器并不可靠，但是在程序中，主进程始终具有最高的内存使用率。

命令

for /f "tokens=2" %%p in ('tasklist /nh /fi "imagename eq explorer.exe" ^| sort /+65') do @set explorerpid=%%p
taskkill /f /pid %explorerpid%

怎么运行的

• tasklist /nh /fi "imagename eq explorer.exe"列出所有具有映像名称的进程explorer.exe。

• sort /+65 从第65个字符（内存使用开始）开始对先前的输出进行排序。

• for /f "tokens=2" %%p in ('COMMAND') do @set explorerpid=%%p设置explorerpid为tokens=2输出的每一行的第二个（）输入（用空格分隔）COMMAND，它是相应的PID。

• 由于tasklist的输出已排序，因此explorerpid保留了声明的PID，并taskkill终止了该过程。

也许您可以告诉资源管理器在标题栏中显示路径，然后根据该条件使用WINDOWTITLE过滤器将其杀死？

• 打开资源管理器
• 按 Alt
• 点击“工具（菜单项）”
• 单击“文件夹选项...（菜单项）”
• 在“文件夹选项”中单击“查看（页面选项卡）”
• 单击以选中“文件夹选项”中的“在标题栏中显示完整路径（仅经典主题）”
• 点击“应用”->“确定”

路径不会以“非经典”主题显示在资源管理器的标题栏中，但是（现在）在那里。它只是不可见。

taskkill /F /FI "WINDOWTITLE eq C:\PathToThing\RunningInExplorer\ToRestart*"

您可能需要暂时切换到经典主题，以确定要重新启动的Explorer实例的路径/标题。

不是100％傻瓜式的，但是标题中没有该（部分）路径的任何资源管理器窗口至少都是安全的。:)

编辑：

由于要捕获标题为“ N / A”的文件，因此可能必须使用批处理文件，以便可以对TASKLIST的结果进行标记化，并使用这些标记结果来使用TASKKIL来按PID终止。

我找到了一个针对StackOverflow.com的答案来解决此问题：

从问题Taskkill无标题的过程？是此答案，其中包括本实施例中的批处理文件：

@echo off
SETLOCAL enabledelayedexpansion
for /f "tokens=*" %%a in ('TASKLIST /V') do (
  set s=%%a
  set p=!s:~27,5!
  set t=!s:~152,3!
  if '!t!'=='N/A' ECHO TASKKILL /PID !p! /T
)

您将需要更改“ TASKLIST / V”命令，使其更特定于Explorer.exe等，但它应该为您提供一个良好的起点。

用最低的PID（进程ID）终止进程。它会先启动，因为进程会按顺序编号。