非英语版本的Microsoft Office中的键盘快捷方式

我对葡萄牙语版的MS Office 2007和2010有很大的疑问。

任何普通应用程序使用的标准快捷方式都已更改。
一些快捷方式不起作用：Ctrl+ s（保存），Ctrl+ f（查找）和Ctrl+ a（全选）。

我想将其配置为使用英文版的快捷方式。

有一个选项允许单独配置每个快捷方式。此外，我必须为每个应用程序进行配置，如果我在Word中进行配置，则必须再次为Excel配置。

无论Office语言如何，如何使用英文版MS Office的快捷方式？

谢谢

我几乎可以肯定，没有内置的方法可以更改MS Office应用程序中的快捷方式。

但是，您可以为此目的使用AutoHotkey。

剧本

^a::
^f::
^s::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a")
           SendPlay, ^e
       if(A_ThisHotKey = "^f")
           SendPlay, ^b
       if(A_ThisHotKey = "^s")
           SendPlay, ^g
    }
    else
        SendPlay, %A_ThisHotKey%
return

这个怎么运作

• ^a::，指定在return语句之前运行脚本的热键之一，其中^表示Ctrl键。

• WinGet, Process, ProcessName, A将活动（A）窗口的进程名称存储在变量中Process。

• if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$")) {...} else ...检查是否Process 匹配正则表达式，即是否匹配字符串WINWORD.EXE或之一EXCEL.EXE。

  • 如果是这样，则执行第一个块。

    • if(A_ThisHotKey = "^a")检查按下的热键是否为Ctrl+ A。

      如果是，它将模拟键炸弹Ctrl+ E，这是选择所有¹的葡萄牙语热键。

  • 否则，SendPlay, %A_ThisHotKey%模拟最初按下的键组合。

    这样，其他应用程序仍然可以发挥应有的作用。

如何使用

1. 下载并安装最新版本的AutoHotkey。

2. ms-office.ahk使用您喜欢的文本编辑器将上述脚本另存为。

3. 双击文件以运行脚本。

4. 如果需要，可以将脚本（或指向脚本的链接）复制到Startup文件夹中。

5. 若要添加其他MS Office应用程序，只需修改正则表达式即可。

   要添加PowerPoint中，例如，更换(WINWORD|EXCEL)的(WINWORD|EXCEL|POWERPNT)。

6. 要添加更多的热键，您必须修改脚本的两个部分。

   要添加Ctrl+ O（Open ...），例如，将行添加^o::到列表的最顶部，将以下行添加到if块内：

   if(A_ThisHotKey = "^o")
       SendPlay, ^a
   

¹至少，我认为是。我从西班牙MS Office那里获取了热键。根据需要进行调整。

根据先前的答案，可以使用更多快捷方式（可以将其添加到先前的答案中）：

^a::
^f::
^s::
^w::
^n::
^u::
^d::
^r::
^b::
^i::
^k::
^g::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a") ;seleccionar rango
           SendPlay, ^e
       if(A_ThisHotKey = "^f") ;buscar
           SendPlay, ^b
       if(A_ThisHotKey = "^s") ;guardar
           SendPlay, ^g
       if(A_ThisHotKey = "^w") ;cerrar
           SendPlay, ^r
       if(A_ThisHotKey = "^n") ;nuevo libro
           SendPlay, ^u
       if(A_ThisHotKey = "^u") ;subrayar
           SendPlay, ^s
       if(A_ThisHotKey = "^b") ;negrita
           SendPlay, ^n
       if(A_ThisHotKey = "^i") ;cursiva
           SendPlay, ^k
       if(A_ThisHotKey = "^d") ;filldown
           SendPlay, ^j
       if(A_ThisHotKey = "^r") ;fill right
           SendPlay, ^d
       if(A_ThisHotKey = "^k") ;hyperlink
           SendPlay, ^!k
       if(A_ThisHotKey = "^g") ;goto
           SendPlay, ^i
    }
    else
        SendPlay, %A_ThisHotKey%
return