如何使用鼠标滚轮让Google Chrome浏览器切换标签页？

在家里，我正在运行Fedora 17，并且已经习惯于使用鼠标滚轮将鼠标悬停在选项卡栏上时快速浏览打开的选项卡。现在对我来说这是非常自然的手势。

我每周至少工作一次（通常是星期一）一次，我尝试在MacBook Pro上运行的chrome上使用相同的技术，但是选项卡不会出现变化。这开始让我发疯。

有没有人有解决方案，可以让我使用滚轮更改OSX的google chrome上的标签？

（我找到了以下Google代码线程，但据我所知，建议的修复方法无法解决该问题-http: //code.google.com/p/chrome-convenience-extension/issues/detail?id= 31）

Chrome Toolbox扩展程序可能是您感兴趣的：

我尚未在OSX上对其进行测试，但它适用于Windows 7，并且那里不应该存在兼容性问题。

在Google网上论坛线程上找到了一个解决方案。将AutoHotKey与以下脚本一起使用：

;; Wheel Scroll Tabs for Google Chrome 

#IfWinActive ahk_class Chrome_WidgetWin_1 
 ~$WheelDown:: 
 ~$WheelUp:: 
    MouseGetPos,, yaxis 
    IfGreater,yaxis,23, Return 
    IfEqual,A_ThisHotkey,~$WheelDown, Send ^{PgDn} 
                                 Else Send ^{PgUp} 
Return 
#IfWinActive

注意：我将其更改为Chrome_WidgetWin_1因为这对我有用。如果那不适合您，请尝试将其更改为Chrome_WidgetWin_0

资源

如果您使用的是Chrome 32+，请使用AutoHotKey（编译脚本）检查此解决方案。Chrome Toolbox无法在31以上的Chrome上运行。

https://plus.google.com/115670442023408995787/posts/WYPqqk2j9UB

或直接使用：

; Mouse Wheel Tab Scroll 4 Chrome
; -------------------------------
; Scroll though Chrome tabs with your mouse wheel when hovering over the tab bar.
; If the Chrome window is inactive when starting to scroll, it will be activated.

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#Warn   ; Enable warnings to assist with detecting common errors.
#SingleInstance force   ; Determines whether a script is allowed to run again when it is already running.
#UseHook Off    ; Using the keyboard hook is usually preferred for hotkeys - but here we only need the mouse hook.
#InstallMouseHook
#MaxHotkeysPerInterval 1000 ; Avoids warning messages for high speed wheel users.

SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
Menu, Tray, Tip, Mousewheel tab scroll for Chrome (1.0.3)

WheelUp::
WheelDown::
    MouseGetPos,, ypos, id
    WinGetClass, class, ahk_id %id%
    If (ypos < 45 and InStr(class,"Chrome_WidgetWin"))
    {
        IfWinNotActive ahk_id %id%
            WinActivate ahk_id %id%
        If A_ThisHotkey = WheelUp
            Send ^{PgUp}
        Else
            Send ^{PgDn}
    }
    Else
    {
        If A_ThisHotkey = WheelUp
            Send {WheelUp}
        Else
            Send {WheelDown}
    }
    Return

我在Ubuntu上的Chrome / Chromium没有任何问题，您所描述的功能对我来说很有效。但是，我目前不得不¹在Windows上使用Chrome，但我错过了此功能。

正如某些人提到的那样，存在一些脚本语言实现，例如AutoHotKey，它仅适用于Windows，而我从来没有觉得需要在Linux / OSX上运行AutoHotKey，AutoIt或任何类似软件。但据我了解，AutoKey和Automator应该是同等的软件。因此，应该有可能针对特定平台以这些语言重新实现基本按键的发送。

这是当前适用于我的解决方案：AutoHotKey社区-tab_switcher-使用鼠标滚轮在任何选项卡式窗口中切换选项卡

你好，

这是另一个使用鼠标滚轮切换选项卡的脚本-该示例脚本适用于Chrome，Firefox和Internet Explorer，但也可用于任何其他程序。

TabJumper(psWindowClass, piStripeYStart, piStripeYEnd)
{
    WinGet, idSearchWindow, ID, ahk_class %psWindowClass%
    MouseGetPos, iMouseX, iMouseY, idHoverWindow
    if (idSearchWindow=idHoverWindow
        && iMouseY>=piStripeYStart
        && iMouseY<=piStripeYEnd ) {

        ControlFocus,, ahk_id %idHoverWindow%
        if RegExMatch(A_ThisHotkey, "i).*wheelup.*")
        {
            ControlSend, ahk_parent, {Control Down}{Shift Down}{Tab Down}, ahk_id %idHoverWindow%
            Sleep, 60
            ControlSend, ahk_parent, {Tab Up}{Shift Up}{Control Up}, ahk_id %idHoverWindow%
        }
        else if RegExMatch(A_ThisHotkey, "i).*wheeldown.*")
        {
            ControlSend, ahk_parent, {Control Down}{Tab Down}, ahk_id %idHoverWindow%
            Sleep, 60
            ControlSend, ahk_parent, {Tab Up}{Control Up}, ahk_id %idHoverWindow%
        }
    }
}

chrome的用法示例：

#SingleInstance, force

~WheelUp::
    TabJumper("Chrome_WidgetWin_1", 8, 88)
return

~WheelDown::
    TabJumper("Chrome_WidgetWin_1", 8, 88)
return

参数说明：

• TabJumper([Window class], [horizontal reaction stripe y axis start], [[horizontal reaction y axis end]])

  这个“水平反应条”怎么样？

  这意味着仅在该窗口条中切换选项卡，窗口的其他部分才能正常使用鼠标滚轮进行响应，例如上下滚动网页。

用法：是的，只需安装AutoHotKey，创建一个新.ahk文件，粘贴两个代码块并执行脚本即可为您提供功能。（我添加的其他标记。）

为了与理解的帮助：{Control Down}{Shift Down}{Tab Down}和{Tab Up}{Shift Up}{Control Up}是按键，一个是迫切和序列控股Crtl+ Shift+ Tab，另一个用于释放他们。这是带有Chrome键盘快捷键的列表。

1. 我个人比较喜欢在所有设备上使用Firefox，而不是Chromium / Chrome，但是在工作中，某些软件制造商无法将重要的浏览器扩展发布为特定产品的经过签名的Firefox扩展（和MS Edge）。就Google桌面软件而言，从我的角度来看，在撰写本文时，大多数软件都不如二十多岁的Techbro在带有Chromebook用例的网络浏览器中做终端机工作。
2. 为此功能（基本）运行一个单独的脚本是错误的，而且太过分了。我完全同意每个人的看法。

有一个简单的chrome扩展名，可让您使用alt +鼠标滚轮向上/向下滚动标签：

https://chrome.google.com/webstore/detail/tab-wheel-scroll/aknfcgiicpmnfhncpljcadokcghjblal?hl=fr

1. 下载并安装X鼠标按钮控件。
2. 从任务栏菜单中打开“设置”。
3. 为Chrome添加新的配置文件。请参考下图。字符串复制：chrome.exe，Intermediate D3D Window，Chrome_WidgetWin_1，Google Chrome Tab Scroll。
4. 选择Simulated Keys为Wheel Up：
5. 输入{CTRL}{PGUP}，选中“仅在配置文件的进程处于活动状态时发送”选项，然后按确定。
6. 重复4 Wheel Down。
7. 重复5 {CTRL}{PGDN}。
8. 单击“应用”。

aa，你完成了🎉