可以从命令行重新连接映射的网络驱动器吗？

我每天都在Windows命令提示符下发现自己需要访问已映射但已断开连接的网络驱动器。我还没有找到可以重新连接该驱动器而不取消映射和重新映射的命令（这导致出现密码猜测游戏，因为我不拥有这些计算机）。我还希望能够对此进行脚本编写，以便驱动器每天晚上都以某种方式断开连接，然后重新连接。

我目前拥有的最快解决方案是：

1. 输入“ start.”以打开资源管理器，
2. Alt- D聚焦地址栏，
3. 键入所需的驱动器号，然后按Enter键，然后等待显示驱动器内容，
4. 然后最后，关闭资源管理器并返回命令提示符。

我知道这是一个小麻烦，但是我经常通过缓慢的VNC或PCAnywhere连接来完成此操作，而通过GUI进行任何操作都很糟糕，所以我只是想知道是否有更好的解决方案。

也许试试pushd \\server\share？

我必须先启动Windows 7，然后才能运行将我连接到公司网络驱动器的VPN程序。因此，我的网络驱动器不会自动重新连接，只有在Windows资源管理器中打开它们才能重新连接它们。

我制作了一个小的批处理文件来启动VPN，重新连接网络驱动器并启动一些我经常使用的应用程序。

在我的批处理文件中，我有以下内容：

REM Connect VPN here...

REM Opens an Explorer window looking at T: forcing a reconnect
Start /min explorer t:\

timeout 3 /nobreak

REM Kill all Explorer windows beginning with "T_drive" in the title
Taskkill /fi "windowtitle eq T_drive*"

REM Finish starting up here...

exit

该Taskkill /fi "windowtitle eq"命令区分大小写！

使用以下命令创建一个批处理文件（refreshletters.cmd）

（这些仅在批处理文件中起作用）

在Win7和XP上进行了测试，以刷新控制台窗口（命令行）中的“断开连接”和“不可用”驱动程序字母。

@echo off
net use |FIND ":" > %temp%\used.txt
FOR /F " tokens=1,2,3 delims= " %%i in (%temp%\used.txt) do (

  if %%i EQU Unavailable  (
    net use %%j %%k
    echo Activated %%j
   ) ELSE (
     if %%i EQU Disconnected (
       pushd .
       cd /d %%j
       dir . %>nul
       if NOT exist %%j\. (
          net use %%j /del /y
          net use %%j %%k
          echo Remapped %%j
          ) else (
             echo Fixed-up %%j
            )
       popd
       ) ELSE (
          echo Checked %%j
          )
     )
 )

这可能是一个愚蠢的问题，但是假设您的“断开连接”驱动器为H :，您是否尝试过直接更改为该驱动器？

它在XPSP3下对我有用：

C:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
Disconnected H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.


C:\>h:

H:\>net use
New connections will be remembered.


Status       Local     Remote                    Network

-------------------------------------------------------------------------------
OK           H:        \\xxxxxx\wfaulk           Microsoft Windows Network
OK                     \\xxxxxxx\business        Microsoft Windows Network
The command completed successfully.

我知道您说“网络使用”对您没有用-但是您可以尝试以下方法。

使用net use / DELETE选项运行批处理文件以删除现有/持久连接，然后可以将net use与/ SAVECRED选项一起使用，以重复使用上一次成功登录时使用的密码。我不确定这是否可以解决您的问题，但值得研究。

我有多个连接相同的问题，并且是间歇性的。当我重新启动计算机时，有时连接是“良好”，有时却不是。由于我在公司的LAN上，所以我没有密码问题，但仍然有其他问题。

我创建了一个名为ex.bat的批处理文件，并将其（以及许多其他内容）存储在我放置在路径中的\ util目录中。我可以输入“ ex h：”，它将运行Windows资源管理器并将其设置为直接转到h：驱动器。这是批处理文件：

start explorer /e,/select,%1

这有效，击键次数更少。或者，如果起初不起作用，请按Enter键以打开h：根文件夹并显示内容。或者，在存在子文件夹“ sub”的地方键入“ ex h：\ sub”。

最近，这个问题似乎变得更加严重，这可能是由于Windows XP安全修补程序之一所致。

要尝试的另一件事是在服务器端。在Windows服务器上，修改注册表项应该可以防止服务器在超时时断开其连接。我几乎在所有服务器上都这样做。该文件是：

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\lanmanserver\parameters]
"autodisconnect"=dword:ffffffff

我遇到了类似的问题，发现我可以从命令行（其中X：是已映射但已断开连接的驱动器）强制使用简单的“ dir x：”重新连接。这是从Server 2003系统到XP和Win7上的已映射驱动器电脑。

我用以下两行创建了一个批处理文件wake_network_drives.bat：

    dir x:
    dir z:

并设置计划的任务，使其在备份程序失败之前每晚运行一次，因为该驱动器有时显示为已断开连接。

只需输入：

NET USE H: \\server\share

（其中H：当然是您的驱动器号）

输入'NET /？USE”以查看此命令为您提供的所有选项。

如果您不反对将这些密码以纯文本格式批量保存，则可以编写一个删除脚本并重新映射包括凭据的脚本。

net use H: /delete
net use H: \\server\share /user:domain\user password /persistent:yes

我知道这不符合您不删除共享的要求，但是它解决了必须记住密码的问题的根源。

TL; DR摘要：使用net use和if exist

创建每晚备份脚本时遇到了一个相关问题。它必须检查计算机是否已打开（使用ping），发送魔术包以在需要时将其打开（使用MC-WOL），等待Windows引导，然后建立与SMB共享的连接并等待它在场。

尽管这里的其他答案很好，但我不希望映射的驱动器号突然出现/消失，也不想断开用户可能正在使用的所有操作，也不希望资源管理器窗口四处闪烁。即目标是零用户分心。

以下代码段可能对您有帮助：

set TARGET_IP=192.168.1.3
set TARGET_PATH=\\%TARGET_IP%\d$\backups
set ATTEMPTS=0

:LOOP

REM Give up eventually
if %ATTEMPTS% GEQ 200 goto NOJOY

REM Wait for IP connectivity to host, and/or burn up a couple seconds before retry
ping -n 1 -w 2000 %TARGET_IP% | find "TTL" > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

REM See if we're already connected, and try to give it a kick
if exist %TARGET_PATH% goto CONNECTED

REM Try to reconnect
net use %TARGET_PATH% > nul
if errorlevel 1 set /a ATTEMPTS+=1 & goto LOOP

:CONNECTED
echo Connected
exit /b

:NOJOY
echo Couldn't connect

如果愿意，可以将上面的IP地址替换为主机名（例如server1）。

net use如果不存在现有连接，则需要。我遇到了一些极端的情况，仅靠这种情况似乎不足以“唤醒”共享（例如，如果以前的连接处于断开状态）。我发现if exists指令有在其他的答案（如提到的替代类似的效果pushd，dir，Explorer，等），但它似乎是一个更轻的方法。

StanZ的答案对我有用，但是我必须能够以编程方式确定任何映射的驱动器而状态为“不”，因为我们域中的用户获得了不同的驱动器映射。我在这里进行编码以作为独立版本运行，该版本net use在实际代码之前和之后执行，以便您可以看到结果，但是您只需要将一个FOR语句（三行）复制到代码中即可获得所需的结果。

@ECHO OFF
::  
:: revision of answer from StanZ on superuser.com at the following url  
:: https://superuser.com/questions/52595/can-a-mapped-network-drive-be-reconnected-from-the-command-line/367910#367910  
:: https://superuser.com/a/367910  
:: which resulted in my  
::  
:: DriveStatusOK.bat  
:: iCharlieC  
::  
SETLOCAL ENABLEEXTENSIONS  
::  
:: you need only copy the one FOR statement (three lines)  
::   to use in your own code  
::   to force status of mapped network drives to OK  
::  
:: "tokens=1-2 delims=: " is used in the for statement  
:: to output only the drive letter from the output of...  
:: net use  
:: is piped to the first findstr which outputs only lines with drive letters  
::   then piped to another findstr to eliminate drives with a status of OK  
::   then piped to another findstr to get lines that start with a status  
::     -in other words, those lines that the first character is a letter-  
::     -this due to the fact that in our domain we have a drive  
::      that is mapped to a letter, but never has a status.  
::      I do not know the reason for this,  
::      but adding that last findstr prevents me from getting an error  
::      from trying to execute a dir on a non-existant drive letter.-  
::   then dir is executed on each drive letter (after appending ":\" to the letter)  
::      and the output redirected to NUL  
::  
:: run net use before as a visual here  
net use  
::  
FOR /F "tokens=1-2 delims=: " %%i in (  
    'net use ^| findstr ":" ^| findstr /i /v "^OK" ^| findstr /i "^[A-Z]"'  
    ) do dir "%%j:" > NUL  
::  
:: run net use after "waking" drive(s)  
net use  
::  
ENDLOCAL  

也许这是一个古老的问题，但在2017年和Windows 10中仍然有意义，因为Windows共享通常不会由于各种原因而重新连接或正确地附加网络共享。基于此问题，并且没有一个切实可行的完整解决方案，我创建了一个Github项目，其中包含一个Scheduler Task和一个VBS，可以通过尝试在恢复或登录后（如果未连接或在线）后重新连接驱动器来解决此问题。

该脚本是完全可配置的，可以根据实际用户的需要进行设置。

Github项目的路径