一个包含多个工作表的Excel（.xlsx）文件如何“拆分”为单独的工作表[n] .xlsx？

我认为标题说明了所有问题，但需要进一步阐述：

我有一个.xlsx文件，其中包含几十张纸。我想将所有这些工作表输出为单独的.xlsx文件。不需要自动命名它们。excel是否具有将图纸导出到单独文件的功能？

它不是内置功能。

但是，如果您运行此代码，它就可以完成任务。

Sub SaveSheets()
    Dim strPath As String
    Dim ws As Worksheet

    Application.ScreenUpdating = False

    strPath = ActiveWorkbook.Path & "\"
    For Each ws In ThisWorkbook.Sheets
        ws.Copy
        'Use this line if you want to break any links:
        BreakLinks Workbooks(Workbooks.Count)
        Workbooks(Workbooks.Count).Close True, strPath & ws.Name & ".xlsx"
    Next

    Application.ScreenUpdating = True
End Sub

Sub BreakLinks(wb As Workbook)
    Dim lnk As Variant
    For Each lnk In wb.LinkSources(xlExcelLinks)
        wb.BreakLink lnk, xlLinkTypeExcelLinks
    Next
End Sub

要运行代码，请执行以下操作：

1. 打开VBA编辑器（Alt+ F11）
2. 在左上角的树中，右键单击您的工作簿并插入一个新模块
3. 将上面的代码复制到该模块中
4. 关闭VBA编辑器
5. 在Excel中，按Alt+ F8运行宏，然后选择SaveSheets

或参阅如何在MS Office中添加VBA？

1. 右键单击Excel工作表的选项卡时，可以选择“ 移动”或“复制...”。

   

2. 在出现的对话框中，您可以选择目标工作簿。选择（新书）。

   

3. 单击确定。您的工作表现在位于新文档中。

我试着彼得·艾伯特的解决方案，它并没有为我工作，所以我找到了一个解决方案这篇文章（“创先争优-保存工作表作为单独的文件”）的计算机怪胎的日记。

效果很好。您应该重命名包含点的图纸，以获取带有.xls扩展名的正确命名的文件。

Sub CreateNewWBS()
Dim wbThis As Workbook
Dim wbNew As Workbook
Dim ws As Worksheet
Dim strFilename As String

    Set wbThis = ThisWorkbook
    For Each ws In wbThis.Worksheets
        strFilename = wbThis.Path & "/" & ws.Name
        ws.Copy
        Set wbNew = ActiveWorkbook
        wbNew.SaveAs strFilename
        wbNew.Close
    Next ws
End Sub

使用说明从Peter Albert的帖子或如何在MS Office中添加VBA来创建和运行此宏。