在Outlook2010中，是否有办法查看当前暂停的提醒？

Outlook 2010中有什么方法可以拉出当前被延后的项目列表？例如，假设两周后，我设置了一个提醒，在星期五弹出来参加下周一的重要午餐会议（我想提醒一下周末之前的周一任务）。提醒在星期五弹出时，我将其暂停三天，以便在星期一午餐之前再次弹出。然后星期一滚来滚去，我的记忆模糊了，我有点偏执，我无意中忽略了星期五的提醒，而没有正确地打oo它。我仍然可以在日历上看到原始约会，但是我需要确保在期望的时候会弹出提醒，这样我才不会错过会议。

Outlook 2010中有什么方法可以拉出当前被延后的提醒列表？这对于那些我完成了一个被延后了提醒的任务的情况也很有帮助，而我现在想拉起被延缓的提醒并取消它。

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

如果您不熟悉VBA，请参见Slipstick的说明页。您将找到有关以下信息：

• 宏安全设置；
• 将代码放置在哪里（可以将常规模块与Insert | Module一起使用）；和
• 如何创建一个按钮。

根据此“ 查看被延后的物品”论坛帖子，无法看到已延后的物品列表。这篇文章建议您通过创建一个显示某些提醒字段的自定义视图，才能看到有限的有用信息。

尝试单击“日历”选项卡，选择“查看”和“更改视图”。然后选择列表。这似乎显示所有提醒的列表。