是否存在一个Excel公式来标识单元格中的特殊字符？

我们大约有3500个文档，其文件名需要手动清理以删除特殊字符，例如方括号，冒号，分号，逗号等。

我有一个文本文件，该文件已转储到excel中，并且我试图创建一个列，如果包含特殊字符，则该列会标记要修改的文件名。伪代码公式为

=IF (cellname contains [^a-zA-z_-0-9], then "1", else "0")

如果该行包含AZ，0-9，-或_以外的任何字符，则无论其大小写如何，都可以标记该行。

有人知道某些对我有用的东西吗？if如果有任何快速简便的方法，我会犹豫编写代码并发表大量声明。

没有代码？但这是如此简短，轻松，美丽......（

RegEx模式[^A-Za-z0-9_-]用于删除所有单元格中的所有特殊字符。

Sub RegExReplace()

    Dim RegEx As Object
    Set RegEx = CreateObject("VBScript.RegExp")
    RegEx.Global = True

    RegEx.Pattern = "[^A-Za-z0-9_-]"
    For Each objCell In ActiveSheet.UsedRange.Cells
        objCell.Value = RegEx.Replace(objCell.Value, "")
    Next

End Sub

编辑

这与我对您的原始问题的回答非常接近。

第二个代码是=RegExCheck(A1,"[^A-Za-z0-9_-]")带有2个参数的用户定义函数。第一个是要检查的单元格。第二个是要检查的RegEx模式。如果模式与您单元格中的任何字符匹配，它将返回1，否则返回0。

如果首先使用ALT+ 打开VBA编辑器F11，然后插入新模块（！）并粘贴以下代码，则可以像使用其他任何普通Excel公式一样使用它。

Function RegExCheck(objCell As Range, strPattern As String)

    Dim RegEx As Object
    Set RegEx = CreateObject("VBScript.RegExp")
    RegEx.Global = True
    RegEx.Pattern = strPattern

    If RegEx.Replace(objCell.Value, "") = objCell.Value Then
        RegExCheck = 0
    Else
        RegExCheck = 1
    End If

End Function

对于RegEx的新用户，我将解释您的模式： [^A-Za-z0-9_-]

[] stands for a group of expressions
^ is a logical NOT
[^ ] Combine them to get a group of signs which should not be included
A-Z matches every character from A to Z (upper case)
a-z matches every character from a to z (lower case)
0-9 matches every digit
_ matches a _
- matches a - (This sign breaks your pattern if it's at the wrong position)

使用类似于nixda的代码的方法，这是一个用户定义的函数，如果单元格中有特殊字符，该函数将返回1。

Public Function IsSpecial(s As String) As Long
    Dim L As Long, LL As Long
    Dim sCh As String
    IsSpecial = 0
    For L = 1 To Len(s)
        sCh = Mid(s, L, 1)
        If sCh Like "[0-9a-zA-Z]" Or sCh = "_" Then
        Else
            IsSpecial = 1
            Exit Function
        End If
    Next L
End Function

用户定义函数（UDF）易于安装和使用：

1. ALT-F11弹出VBE窗口
2. ALT-I ALT-M打开一个新模块
3. 将内容粘贴并关闭VBE窗口

如果保存工作簿，则UDF将随其一起保存。如果要在2003年以后使用Excel版本，则必须将文件另存为.xlsm而不是.xlsx

删除UDF：

1. 如上调出VBE窗口
2. 清除代码
3. 关闭VBE视窗

要从Excel使用UDF：

=特殊（A1）

要总体上了解有关宏的更多信息，请参见：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/zh-CN/library/ee814735(v=office.14).aspx

和

http://www.cpearson.com/excel/WritingFunctionsInVBA.aspx

有关UDF的细节

必须启用宏才能使其正常工作！

这是一个条件格式解决方案，它将用特殊字符标记记录。

只需对使用以下（极长）公式的数据应用新的条件格式设置规则，该规则A1就是文件名列中的第一条记录：

=SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<48)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<>45))+SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))>57)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<65))+SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))>90)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<97)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<>95))+SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))>122)*1)

此公式检查每个文件名的每个字符，并确定其ASCII码是否在允许的字符值之外。不幸的是，允许的字符代码并不都是连续的，因此这就是公式必须使用SUMPRODUCTs之和的原因。该公式返回存在的不良字符数。任何返回值大于0的单元格都会被标记。

例：

我使用了另一种方法来查找特殊字符。我为每个允许的字符创建了新列，然后使用如下公式来计算每个行条目（Z2）中允许的字符有多少次：

AA2=LEN($Z2)-LEN(SUBSTITUTE($Z2,AA$1,""))
AB2=LEN($Z2)-LEN(SUBSTITUTE($Z2,AB$1,""))
...

然后，我对每一行中允许的字符数求和，然后将其与行条目的总长度进行比较。

BE2=LEN(Z2)
BF2=SUM(AA2:BC2)-BE2

最后，我在最后一列（BF2）上排序以找到负值，这使我进入需要更正的列。