假设D:驱动器中有一些文件夹：

D:\Air
D:\Abonden
D:\All
D:\Whatever

我想删除所有以“ A”开头的文件夹（包括所有子文件夹和文件）。我尝试了以下命令：

rmdir D:\A* /s /q

我收到一个错误，但是:(

文件名，目录名称或卷标签语法不正确。

该del命令适用于*，但我也需要删除文件夹。
有没有办法通过rmdir命令来实现？

cd c:\temp
for /f %i in ('dir /a:d /s /b A*') do rd /s /q %i

使用此来测试：

for /f %i in ('dir /a:d /s /b A*') do echo rd /s /q %i

这将把要运行的命令输出到命令提示符中，并允许您查看发生了什么。

请记住，这还将搜索子文件夹，例如“ C：\ temp \ jjj \ aaa”，并将删除aaa文件夹。如果只希望查看顶级文件夹“ C：\ temp \ aaa”，"/s"则从命令中删除。

关键在于A *，您可以在其中输入搜索字符串。这将接受通配符，如aaa*，aaa*和*aaa*如果你想让它。

使用通配符删除文件夹

单独的rmdir/ rd命令不支持通配符（即*和?）。您可以通过将其包装在for循环中。

用法示例

for /d %G in ("X:\A*") do rd /s /q "%~G"

注意：在删除文件和文件夹时，您可能希望将rd命令替换为echo要先。这样，您可以确保实际上不应删除的所有内容。

多种模式

为了删除匹配不同模式的多个文件夹，语法没有太大不同。正如@dbenham正确指出的那样，单行命令就足够了。您还可以指定不同的路径：

for /d %G in ("X:\A*","Y:\Whatever\B*","Z:\C?D") do rd /s /q "%~G"

奖励-检查文件夹是否存在

如果要检查特定文件夹是否存在，可以使用以下命令：

dir /b /a:d "X:\A*" >nul 2>&1 && echo Folders exist. || echo No folders found.

进一步阅读

• / d-在目录中循环
• 有条件的执行
• 命令行参考

还没有人告诉OP关于文件的信息吗？

forfiles /P D:\ /M A* /C "cmd /c if @isdir==TRUE rmdir /s /q @file"

/ P是路径名-搜索开始的位置
/ M是搜索掩码，查找以A开头的文件
/ C是要执行的命令
/ S是递归子文件夹（此处未包含，因为op没有询问）

adn31415答案是正确的，但是如果将其放在批处理或cmd脚本中会中断。我敲了几个小时，直到我弄清楚了这是你的用法。

在DOS命令窗口中：

for /d %G in ("X:\A*") do rd /s /q "%~G"

在批处理或cmd脚本中：

for /d %%G in ("X:\A*") do rd /s /q "%%~G"

如果要将其放入“ .bat”或“ .cmd”文件中，则需要将“％”字符加倍。