您可以使用我的脚本Batch_Admin自动将管理员提升为可在任何类型的批处理自身脚本，BAT或.CMD中使用。此功能可确保在标准环境中使用标准工具在不同Windows系统中以相同方式进行工作。它使用几个标准的内置Windows命令。不要使用任何其他外部脚本。它可以用来以管理员身份调用任何程序，而不仅仅是脚本Batch。创建一个小的脚本即可，然后调用需要权限Administartor的程序。将此放置在任何搜索PATH文件夹中（来自％PATH％）。
要使用它，您只需在其父批脚本中插入以下行（完全相同）即可，该脚本将以管理员身份运行。最好在父脚本的顶部完成此操作，最好是先进行此操作，然后再通过CALL调用一些子脚本（请参见下面的详细说明）。
net session >nul 2>nul&if errorlevel 1 Batch_Admin "%~0" %*
可以将其插入任何由CALL语法调用的子脚本中。在消息仍然显示时不具有管理员权限，例如。调用Batch_Admin之前的5秒钟，将变量“ ShowAdminInfo”设置为秒数
SET ShowAdminInfo=5
net session >nul 2>nul&if errorlevel 1 Batch_Admin "%~0" %*
所以它是如何工作的：
•通过VBScript调用UAC.ShellExecute以获取用户权限
•批处理运行脚本，或者BAT或CMD
•脚本调用方的引号中可以包含长名称空间
•退回从命令行传递来的主脚本调用的所有参数，就好像没有传输调用并从头开始一样，还带有特殊字符，例如感叹号（！）和百分比（％），以及带括号（）
•如果呼叫发生在主脚本所在的目录中，则保存主脚本位置
•如果我们在自己之前设置变量“ ShowAdminInfo”，则辅助显示一条消息，例如。持续5秒钟，这可能会阻止管理员立即提供附加信息以及做出明智决定的权利。必须设置的设置示例：SET ShowAdminInfo = 5默认情况下，由于未定义此变量，因此不会显示。
•该脚本还在系统搜索路径％PATH％中以及从网络资源中调用，例如：\ Computer \ share \ test.bat
•防止在脚本几乎同时调用多个Batch_Admin时编写必要的辅助文件时产生误解。它使用1到100之间的随机数
•但是，最好是在父脚本上使用它。过渡到管理员权限始终要求您在新窗口，新环境中完全重新运行脚本，而不必求助于先前在脚本中设置的变量，并且这些变量的值没有传递，然后以管理员身份调用。只是脚本将再次执行。
在完整的脚本Batch_Admin下面。有关此内容的更多信息，请访问我的网站。
将以下文本复制到记事本中，并将其另存为：Batch_Admin.bat
@echo off
if "%~1"=="" (echo *** Batch_Admin ***&echo.&echo Automatically get admin rights for another Batch. See info inside.&TIMEOUT /T 30>nul&goto:eof)
:: A D M I N I S T R A T O R - Automatically get admin rights for script batch. Paste this on top: net session >nul 2>nul&if errorlevel 1 Batch_Admin "%~0" %*
:: Also keep Batch directory localisation and then set variable: PATH_BAT
:: if earlier variable "ShowAdminInfo" is empty (not defined) then no info, else showing info with number of seconds
::
:: Elaboration: Artur Zgadzaj
setlocal
setlocal DisableDelayedExpansion
SET "Localy="
if exist "%~1" SET "Localy=YES"
if exist "%~1.BAT" SET "Localy=YES"
if exist "%~1.CMD" SET "Localy=YES"
if defined Localy FOR %%I IN ("%~1") DO SET "PATH_BAT=%%~dI%%~pI"
SET P1=%~1
SET Parameters=%*
SET Parameters=%Parameters:!=^^!%
setlocal EnableDelayedExpansion
SET Parameters=!Parameters:%P1%=!
SET Parameters=!Parameters:%%=%%%%!
setlocal DisableDelayedExpansion
SET Parameters=%Parameters:~3%
net session >nul 2>nul&if not errorlevel 1 goto Administrator_OK
if not defined ShowAdminInfo goto skip_message_Administrator
echo.
echo Script: %~1
echo.
echo *****************************************************************
echo *** R U N N I N G A S A D M I N I S T R A T O R ***
echo *****************************************************************
echo.
echo Call up just as the Administrator. You can make a shortcut to the script and set:
echo.
echo shortcut ^> Advanced ^> Running as Administrator
echo.
echo Alternatively run once "As Administrator"
echo or in the Schedule tasks with highest privileges
echo.
echo Cancel Ctrl-C or wait for launch %ShowAdminInfo% seconds ...
TIMEOUT /T %ShowAdminInfo% > nul
:skip_message_Administrator
MD %TEMP% 2> nul
SET /A $Admin$=%RANDOM% * 100 / 32768 + 1
SET "Percent="
del "%TEMP%\$Admin_%$Admin$%_Test.bat" 2>nul
echo %Parameters% > "%TEMP%\$Admin_%$Admin$%_Test.bat"
if not exist "%TEMP%\$Admin_%$Admin$%_Test.bat" SET Percent=^"
del "%TEMP%\$Admin_%$Admin$%_Test.bat" 2>nul
echo @SET "PATH_BAT=%PATH_BAT%" > "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
echo @SET "BatchFullName=%BatchFullName%" >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
if defined Localy (echo @CD /D "%PATH_BAT%" >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat")
echo @"%~1" %Parameters% %Percent% >> "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat"
echo SET UAC = CreateObject^("Shell.Application"^) > "%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
echo UAC.ShellExecute "%TEMP%\$Admin_%$Admin$%_Batch_Start.bat", "", "", "runas", 1 >> "%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
"%TEMP%\$Admin_%$Admin$%_Batch_getPrivileges.vbs"
endlocal
exit /B
:Administrator_OK
"%~1" %Parameters%
goto:eof
REM *** A D M I N I S T R A T O R - Automatically get admin rights (The End) ***
