添加按钮以复制Excel行

我想在电子表格的行中添加一个按钮，当我单击按钮时，该按钮会将内容从一个单元格复制到另一个单元格。我已经找到了执行此操作的代码，但是，我希望能够将按钮复制到新行并使其在该行上工作，并且该行上有单元格，而无需进入并更改代码。

下面的代码是我所拥有的代码，但它仅针对一行编写：

Sub CopyValue()

    ActiveSheet.Range("O7").Value = ActiveSheet.Range("K7")
    ActiveSheet.Range("R7").Value = ActiveSheet.Range("N7")

End Sub

并将K7细胞内容复制到O7细胞内容等。

如果我复制下一行的按钮，它对该行不起作用，除非我进入并更改代码，这意味着添加一个新的按钮或宏名称和代码来执行此操作。

我想一次又一次地复制并添加一行，让它在那一行上运行。单元格公式以这种方式工作，但如何通过单击同一行上的按钮来触发单元格公式？

我需要能够在数百或更多行上执行此操作，只需复制和粘贴，或复制行，或将按钮复制并粘贴到新行。

我有Excel 2007。

与为单个ActiveX或表单控件按钮生成代码相比，您可以使用以下VBA代码更轻松地完成目标。

以下VBA允许用户双击指定列中的单元格（“按钮列”），代码将复制用户在您指定的源列到目标列中双击的同一行上的值。此代码适用于工作表中的所有行，而无需您以任何方式修改代码。

不要被代码重复引用第1行上的单元格（例如O1和K1）抛弃。在每种情况下，.Column都使用该属性，因为我们只对相关列感兴趣。将被操纵的行始终是用户双击的同一行。

在Excel VBA编辑器中（按Alt+ F11打开）导航到工作表的模块，然后粘贴以下代码：

Private Sub
Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
On Error GoTo Quit
'Copy values between columns on same row that user double-clicks

'Quit if Target range includes more than one cell
If Target.Count > 1 Then Exit Sub

With ActiveSheet

    'Here, specify the worksheet column the user can double-click to activate this
    'routine.  For the "B" column, in the Range method specify cell "B1" (all cells
    'in column will be used, not just that on row 1).
    If Target.Column = .Range("B1").Column Then
        .Cells(Target.Row, .Range("O1").Column) = .Cells(Target.Row, .Range("K1").Column)
        .Cells(Target.Row, .Range("R1").Column) = .Cells(Target.Row, .Range("N1").Column)

        Cancel = True   'Cancel the double-click
    End If

    'Here you can specify a second "button column" with its own set of copy actions.
    If Target.Column = .Range("C1").Column Then
        .Cells(Target.Row, .Range("E1").Column) = .Cells(Target.Row, .Range("F1").Column)
        .Cells(Target.Row, .Range("G1").Column) = .Cells(Target.Row, .Range("H1").Column)

        Cancel = True   'Cancel the double-click
    End If

End With

Quit:
End Sub

如上所述，当用户双击列中的任何单元格时，将触发代码B。要更改此设置，请修改此行代码以指向您希望充当“按钮列”的列：

If Target.Column <> .Range("B1").Column Then Exit Sub

其余的代码应该是不言自明的，但问你有任何问题。

编辑：我更改了VBA以允许两个按钮列，每个列都能够在不同的源列和目标列之间复制值。

我建议使用双击Z列中单元格的单元格按钮方法来触发工作Worksheet_BeforeDoubleClick表事件宏。

右键单击工作表的名称选项卡，然后选择View Code。当VBE打开时，将以下内容粘贴到标题为Book1 - Sheet1（代码）的表格中。请注意，这不是包含您之前用作示例的代码的模块表。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Not Intersect(Target, Range("Z:Z")) Is Nothing Then
        If LCase(Target.Value) = "xfer vals" Then
            Cancel = True
            Me.Range("O" & Target.Row) = Me.Range("K" & Target.Row).Value
            Me.Range("R" & Target.Row) = Me.Range("N" & Target.Row).Value
        End If
    End If
End Sub

将其粘贴到工作表的代码表中，将Z：Z范围调整为要用作伪按钮的列。我还添加了一个条件，单元格必须包含某种形式的xfer vals作为文本值，所以如果你愿意，可以改变它。完成修改后，点击Alt+ Q返回工作表。

在Z列中，键入xfer vals（或您更改为的任何内容）到包含您希望传输的值的单元格中。如果您愿意，可以为单元格添加背景填充和/或边框。双击它将传输值。

您应该能够将该行公式/值（s）/伪按钮复制到任何新行，并使按钮按照新行工作。

请注意，我.Values将目标更改为源。如果您只想在代码行的一侧使用它，则源是使用它的适当位置。