如何在awk打印命令上使用排序？

我正在编写的awk脚本中有几个命令：

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2}

哪个输出：

Here are some players and their numbers, sorted by last name
Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55

如何在awk脚本中使用sort命令仅对玩家及其编号进行排序？

您可以添加| sort -k2到您的命令。这将基于第二列按字母顺序排序。

例：

$ echo "Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55" | sort -k2

结果是

Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

尽管我不建议这样做（考虑到通过外部sort命令传递结果的相对简单性），但至少可以使用最新版本的GNU awk（至少为4.0 IIRC）执行此操作，如使用gawk对数组值和索引进行排序中所述

假设您将数据存储在索引为的关联数组中，这是实现方法Firstname Lastname。首先，您需要定义一个自定义比较函数，该函数将分割索引，Lastname然后首先进行比较（例如，平局），Firstname例如

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

现在您可以使用PROCINFO["sorted_in"]@zwets注释中提到的数组排序方法

PROCINFO["sorted_in"] = "mycmp";
for(i in a) print i, a[i];

把它放在一起

#!/usr/bin/gawk -f

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

{
  a[$1" "$2] = $3;
}

END {
  PROCINFO["sorted_in"] = "mycmp";
  for(i in a) print i, a[i];
}

测试：

$ ./namesort.awk yourfile
Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

在awk的较低版本或较旧版本中，最好的选择是存储通过索引的数据，然后Lastname Firstname按常规排序asorti，然后在遍历数组以进行打印时拆分并交换索引的字段：

awk '
  {a[$2" "$1]=$3} 
  END {
    n=asorti(a,b); for (i=1;i<=n;i++) {split(b[i],s); print s[2], s[1], a[b[i]]}
}' yourfile

要sort仅由空格分隔的第二个字段，请使用key -k2,2：

... | sort -k2,2

默认情况下sort按字典顺序进行排序。

请注意，如果您没有提及排序键的最后一个字段（即，如果您仅使用它），-k2则可能无法获得所需的结果，因为sort根据第二个字段开始的所有字段都会如此。

同时检查man sort。

尝试

awk -f myscript.awk | sort -k2

其中myscript.awk仅包含awk命令。

如果您的实际脚本是shell脚本，则可以选择以下几种方法：

• 通过排序输出管道。 ./myscript.bash | sort -k2

• 将代码重写为脚本内的函数，
  而不是

  $ cat t1
  #!/bin/bash
  for i in 2 4 3 1 5;
  do
    echo $i
  done
  
  $ ./t1
  2
  4
  3
  1
  5
  

  做

  $ cat t2
  #!/bin/bash
  function foo {
    for i in 2 4 3 1 5;
    do
      echo $i
    done
  }
  foo | sort
  
  $ ./t2
  1
  2
  3
  4
  5
  

但是请注意，您也可以将排序应用于do ... done结构，而不是创建函数。

    do
       echo $i
    done | sort

要对要打印的数据进行排序：

• 假设您要打印第二个字段（用空格隔开），请使用以下命令：

  awk '{print $2}' data.txt | sort
  

  例如：

  $cat>data.txt
  1 Kedar 20
  2 Amit 30
  3 Rahul 21
  ^C
  
  $awk '{print $2}' | sort
  Amit
  Kedar
  Rahul
  

• 如果要打印全部data.txt但在第2列上排序，则：

  $awk '{print}'|sort -k2
  2 Amit 30
  1 Kedar 20
  3 Rahul 21
  

在您的需求中使用此逻辑。

您可以使用man sort更有趣的功能sort。

下面呢：

 awk 'BEGIN{str="1\n2\n3\n4"; system("echo -e \""str"\" | sort -r")}'

它在我测试时有效。

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2"}

要将输出排序到文件：

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2 > sortedFile"}