将shell变量作为/ pattern /传递给awk

在我的一个shell函数中具有以下内容：

function _process () {
  awk -v l="$line" '
  BEGIN {p=0}
  /'"$1"'/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '
}

，因此当称为时_process $arg，$arg将作为传递$1，并用作搜索模式。它以这种方式工作，因为shell扩展$1代替了awk模式！也l可以在awk程序中使用，用声明-v l="$line"。一切都很好。

是否有可能以相同的方式将模式作为变量进行搜索？

以下操作无效，

awk -v l="$line" -v search="$pattern" '
  BEGIN {p=0}
  /search/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '

，因为awk不会解释/search/为变量，而是按字面意义。

使用awk的~运算符，您无需在右侧提供文字正则表达式：

function _process () {
    awk -v l="$line" -v pattern="$1" '
        $0 ~ pattern {p=1} 
        END {if(p) print l >> "outfile.txt"}
    '  
}

尽管这样会更有效（不必读取整个文件）

function _process () {
    grep -q "$1" && echo "$line"
}

取决于模式，可能想要 grep -Eq "$1"

awk  -v pattern="$1" '$0 ~ pattern'

具有这样一个问题，awk扩展ANSI C转义序列（如\n为换行，\f为的形式进料，\\用于反斜杠等）中$1。因此，如果$1包含正则表达式中常见的反斜杠字符（对于GNU awk4.2或更高版本，以开头@/和以结尾的值/也是一个问题），则成为一个问题。不受此问题困扰的另一种方法是编写它：

PATTERN=$1 awk '$0 ~ ENVIRON["PATTERN"]'

到底有多糟糕取决于awk实现。

$ nawk -v 'a=\.' 'BEGIN {print a}'
.
$ mawk -v 'a=\.' 'BEGIN {print a}'
\.
$ gawk -v 'a=\.' 'BEGIN {print a}'
gawk: warning: escape sequence `\.' treated as plain `.'
.
$ gawk5.0.1 -v 'a=@/foo/' BEGIN {print a}'
foo

awk对于有效的转义序列，所有s的工作都相同：

$ a='\\-\b' awk 'BEGIN {print ENVIRON["a"]}' | od -tc
0000000   \   \   -   \   b  \n
0000006

（$a原样通过的内容）

$ awk -v a='\\-\b' 'BEGIN {print a}' | od -tc
0000000   \   -  \b  \n
0000004

（\\更改为，\并\b更改为退格字符）。

尝试类似的东西：

awk -v l="$line" -v search="$pattern" 'BEGIN {p=0}; { if ( match( $0, search )) {p=1}}; END{ if(p) print l >> "outfile.txt" }'

不，但是您可以简单地将模式插入到传递给awk的双引号字符串中：

awk -v l="$line" "BEGIN {p=0}; /$pattern/ {p=1}; END{ if(p) print l >> \"outfile.txt\" }"

请注意，您现在必须转义双引号的awk文字，但这仍然是实现此目的的最简单方法。

您可以使用eval函数，该函数在本示例中在运行awk之前解析nets变量。

nets="searchtext"
eval "awk '/"${nets}"/'" file.txt