在zsh中测试LS_COLORS

几年前我发现了一个有趣的代码片段，该片段根据在中设置的颜色以相应的颜色打印每种文件类型LS_COLORS。不幸的是，我不再记得链接了。

这是有test_colors.sh问题的代码段

eval $(echo "no:global default;fi:normal file;di:directory;ln:symbolic link;pi:named pipe;so:socket;do:door;bd:block device;cd:character device;or:orphan symlink;mi:missing file;su:set uid;sg:set gid;tw:sticky other writable;ow:other w\
ritable;st:sticky;ex:executable;"|sed -e 's/:/="/g; s/\;/"\n/g')                                                                                                                                                                            
{                                                                                                                                                                                                                                           
  IFS=:                                                                                                                                                                                                                                     
  for i in $LS_COLORS                                                                                                                                                                                                                       
  do                                                                                                                                                                                                                                        
    echo -e "\e[${i#*=}m$( x=${i%=*}; [ "${!x}" ] && echo "${!x}" || echo "$x" )\e[m"                                                                                                                                                       
  done                                                                                                                                                                                                                                      
}   

该代码段在中效果不错bash，但在中效果不佳，zsh我也不知道为什么。当我运行它时，zsh出现以下错误：

> sh .test_colors.sh
.eval_colors:1: * not found
[00:fi=00:di=01;34:ln=01;36:pi=40;33:so=01;35:do=01;35:bd=40;33;01:cd=40;33;01:or=40;31;01:su=37;41:sg=30;43:tw=30;42:ow=34;42:st=37;44:ex=01;32:*.tar=01;31:*.tgz=01;31:*.arj=01;31:*.taz=01;31:*.lzh=01;31:*.zip=01;31:*.z=01;31:*.Z=01;31:*.gz=01;31:*.bz2=01;31:*.deb=01;31:*.rpm=01;31:*.jar=01;31:*.jpg=01;35:*.jpeg=01;35:*.gif=01;35:*.bmp=01;35:*.pbm=01;35:*.pgm=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.tiff=01;35:*.png=01;35:*.mov=01;35:*.mpg=01;35:*.mpeg=01;35:*.avi=01;35:*.fli=01;35:*.gl=01;35:*.dl=01;35:*.xcf=01;35:*.xwd=01;35:*.flac=01;35:*.mp3=01;35:*.mpc=01;35:*.ogg=01;35:*.wav=01;35:m

更新（2011年11月1日）

我在下面测试了@StéphaneGimenez的脚本。我注意到某些字符似乎无法正确转义。有什么想法吗？

答案： 请参阅@StéphaneGimenez答案的评论。

用更简洁的方式为zsh编写的内容：

#!/bin/zsh

typeset -A names
names[no]="global default"
names[fi]="normal file"
names[di]="directory"
names[ln]="symbolic link"
names[pi]="named pipe"
names[so]="socket"
names[do]="door"
names[bd]="block device"
names[cd]="character device"
names[or]="orphan symlink"
names[mi]="missing file"
names[su]="set uid"
names[sg]="set gid"
names[tw]="sticky other writable"
names[ow]="other writable"
names[st]="sticky"
names[ex]="executable"

for i in ${(s.:.)LS_COLORS}
do
    key=${i%\=*}
    color=${i#*\=}
    name=${names[(e)$key]-$key}
    printf '\e[%sm%s\e[m\n' $color $name
done

您需要转义=in，${i%=*}因为否则后缀模式将=*进行=扩展，因此=被解释为命令名。这是* not found错误的原因。

Zsh默认情况下不会在变量替换中拆分单词，因此$LS_COLORS会扩展为单个单词。要使for循环在的冒号分隔部分上起作用$LS_COLORS，请使用for i in $=LS_COLORS。或者更习惯地在zsh中使用，而不使用IFS，而是明确指定如何拆分：for i in ${(s.:.)LS_COLORS}。

${!x}表示“名称为$x” 的变量的值的语法专用于bash。Zsh具有等效的构造，即P 参数扩展标志：${(P)x}。