从撤消文件撤消更改时，可以得到通知吗？

我已经在Vim中使用撤消文件功能了一段时间了。这是一个非常好的功能。

但是，令人烦恼的是，很容易意外撤消上次打开文件时所做的更改。可能是2分钟前，一个小时前，上周或一个月前。

例如，假设我打开了一个文件，进行了一些更改，然后关闭并更改了一些其他文件，然后发现我不需要进行更改，或者可能只是一些临时调试语句。

以前，我只能按住该u键，直到Vim说“已经是最旧的更改” :wq，然后完成。但是现在我必须非常小心，不要撤消上次打开文件时所做的更改。没有明显的方法可以看到您何时执行此操作。

有什么办法可以使这个更明确吗？例如，将其显示在某个地方，发出警告甚至要求确认。

我有这个确切的问题。这是我添加到vimrc中为我修复的内容：

" Always write undo history, but only read it on demand
" use <leader>u to load old undo info
" modified from example in :help undo-persistence

if has('persistent_undo')
  set undodir=~/.vim/undo " location to store undofiles
  nnoremap <leader>u :call ReadUndo()<CR>
  au BufWritePost * call WriteUndo()
endif

func! ReadUndo()
  let undofile = undofile(expand('%'))
  if filereadable(undofile)
    let undofile = escape(undofile,'% ')
    exec "rundo " . undofile
  endif
endfunc

func! WriteUndo()
  let undofile = escape(undofile(expand('%')),'% ')
  exec "wundo " . undofile
endfunc

请注意，您没有设置该undofile选项。如果有，您需要从vimrc中删除它。

撤消现在可以正常使用。但是我们确实使用中的wundo命令手动写入撤消文件BufWritePost。

该ReadUndo()功能使用手动读取撤消文件rundo并设置undofile选项。现在我们可以使用它u来进一步追溯历史。我将此映射到<Leader>u。

这可能会更好。它会覆盖以前的撤消信息，因此您无法返回到之前编辑文件的时间。但是我自己并不需要。

哦，哦，终于有机会炫耀这个漂亮的命令！

Vim可以“回到过去”。它有一个:earlier命令...

                                                        :ea :earlier            
:earlier {count}        Go to older text state {count} times.                   
:earlier {N}s           Go to older text state about {N} seconds before.        
:earlier {N}m           Go to older text state about {N} minutes before.        
:earlier {N}h           Go to older text state about {N} hours before.          
:earlier {N}d           Go to older text state about {N} days before.           

:earlier {N}f           Go to older text state {N} file writes before.          
                        When changes were made since the last write             
                        ":earlier 1f" will revert the text to the state when    
                        it was written.  Otherwise it will go to the write      
                        before that.                                            
                        When at the state of the first file write, or when      
                        the file was not written, ":earlier 1f" will go to      
                        before the first change.                                

...可以将文件还原到以前的状态。可以以多种方式使用它。

• 如果您可以大致估计一下进行这些更改所花费的时间，则可以在此命令中花些时间。或者，例如，如果您知道在过去的一天中没有更改文件（要撤消的更改除外），则可以使用

  :earlier 1d
  

• 如果自撤消更改以来仅写入（保存）了一次文件，或者根本没有保存文件，则可以使用

  :earlier 1f
  

  如:help文本中所述，如果您只是编写文件，它将恢复为先前编写的版本；如果您没有进行任何更改，则将恢复为上次保存的版本。

这不能精确回答您的问题，但听起来有点像XY问题。

更新2015-06-28：我修复了一个小错误，并将其作为插件发布。插件代码稍好一点，因为它在移动光标后会再次发出警告；我建议您使用该插件。

superjer的答案很有效，但不幸的是，您只能撤消上一个Vim会话中的更改，而不能撤消所有先前的Vim会话中的更改。

这是因为wundo覆盖撤消文件。它没有合并。据我所知，没有办法解决这个问题。

因此，这是我的替代解决方案，当您撤消撤消文件中的更改时，它将显示一条红色的大警告消息。

这类似于Ingo Karkat的答案，但是它不需要外部插件，并且有一些细微的差异（显示警告而不是发出哔声，不需要您再按u两次）。

请注意，这只是修改u和<C-r>结合，并且不与U，:undo和:redo命令。

" Use the undo file
set undofile

" When loading a file, store the curent undo sequence
augroup undo
    autocmd!
    autocmd BufReadPost,BufCreate,BufNewFile * let b:undo_saved = undotree()['seq_cur'] | let b:undo_warned = 0
augroup end 

" Remap the keys
nnoremap u :call Undo()<Cr>u
nnoremap <C-r> <C-r>:call Redo()<Cr>


fun! Undo()
    " Don't do anything if we can't modify the buffer or there's no filename
    if !&l:modifiable || expand('%') == '' | return | endif

    " Warn if the current undo sequence is lower (older) than whatever it was
    " when opening the file
    if !b:undo_warned && undotree()['seq_cur'] <= b:undo_saved
        let b:undo_warned = 1
        echohl ErrorMsg | echo 'WARNING! Using undofile!' | echohl None
        sleep 1
    endif
endfun

fun! Redo()
    " Don't do anything if we can't modify the buffer or there's no filename
    if !&l:modifiable || expand('%') == '' | return | endif

    " Reset the warning flag
    if &l:modifiable && b:undo_warned && undotree()['seq_cur'] >= b:undo_saved
        let b:undo_warned = 0
    endif
endfun

我有以下内容，当撤消达到持久的缓冲区内容时，它将停止并发出蜂鸣声。

runtime autoload/repeat.vim " Must load the plugin now so that the plugin's mappings can be overridden.
let s:undoPosition = []
function! s:StopAtSavedPosition( action )
    " Buffers of type "nofile" and "nowrite" never are 'modified', so only do
    " the check for normal buffers representing files. (Otherwise, the warning
    " annoyingly happens on every undo.)
    if ingo#buffer#IsPersisted() && ! &l:modified && s:undoPosition != ingo#record#PositionAndLocation(1)
        " We've reached the undo position where the buffer contents correspond
        " to the persisted file. Stop and beep, and only continue when undo is
        " pressed again at the same position.
        call ingo#msg#WarningMsg(a:action . ' reached saved buffer state')
        execute "normal! \<C-\>\<C-n>\<Esc>" | " Beep.

        let s:undoPosition = ingo#record#PositionAndLocation(1)
        return 1
    else
        let s:undoPosition = []
        return 0
    endif
endfunction
nnoremap <silent> u     :<C-U>if ! &l:modifiable<Bar>execute 'normal! u'<Bar>elseif ! <SID>StopAtSavedPosition('Undo')<Bar>call repeat#wrap('u',v:count)<Bar>endif<CR>
nnoremap <silent> <C-R> :<C-U>if ! &l:modifiable<Bar>execute "normal! \<lt>C-R>"<Bar>elseif ! <SID>StopAtSavedPosition('Redo')<Bar>call repeat#wrap("\<Lt>C-R>",v:count)<Bar>endif<CR>

这与repeat.vim插件集成在一起；它需要我的ingo-library插件。

我想我也会接受一个给出命令的命令，该命令将文件恢复为自上次打开文件以来的状态。（或者更好，跳回到该撤消状态。）

>丰富

我真的很喜欢这个引用的想法，所以我下了:Revert命令。我希望您会发现与您的问题有关。

function! s:Real_seq(inner, outer) abort
  let node = a:outer
  for i in a:inner
    if has_key(i, 'alt')
      call s:Real_seq(i.alt, deepcopy(node))
    endif
    if has_key(i, 'curhead')
      return {'seq': node.seq}
    endif
    let node.seq  = i.seq
  endfor
endfunction

function! s:Get_seq(tree) abort
  let query = s:Real_seq(a:tree.entries, {'seq': 0})
  if (type(query) == 4)
    return query.seq
  else
    return undotree()['seq_cur']
  endif
endfunction

au BufReadPost,BufNewFile * if !exists('b:undofile_start') 
      \ | let b:undofile_start = s:Get_seq(undotree()) | endif

command! -bar Revert execute "undo " . get(b:, 'undofile_start', 0)

辅助功能Get_seq和Real_seq基于undotree，是必要的，因为undotree()['seq_cur']有时是不够的，在查明撤销树当前位置。您可以在此处了解更多信息。