我喜欢Atom和Sublime Text处理行折叠的方式，其中每个折叠的第一行都是可见的（语法高亮显示完整），并且在该行的末尾附加了一个标记来指示折叠。

请参阅下面的屏幕快照，比较Vim的缩进折叠（顶部）与Atom的折叠（底部）：

Vim为每折指定两行。第一行用作标题，第二行描述有关折页的一些信息（折页内的行数和文本）。

Atom仅使用一行，并在该行的末尾使用一个小标记来指示折叠，并在左侧的行号中添加颜色。Atom的折叠样式使用的屏幕空间更少，但仍可以传达我真正需要的所有信息。

我偏爱Atom折叠样式。我认为，这看起来更干净，更一致，尤其是当连续列出多个方法或属性时（如上图所示）。

有没有办法大致估算Vim中Atom的折叠样式？

两行与一行

在Vim中，折痕内的所有行都将折叠为单行，然后该'foldtext'选项确定这些线的提要（通常是破折号，折线的数量以及第一（或全部）行的内容）。

在您的示例中，在Vim中，仅{...}参数块本身被折叠；上面的行（使用参数）不是折叠的一部分。相反，在另一个编辑器中，使用参数的那一行属于该折叠，而其折叠文本（使用Vim术语）是该行的内容以及附加的标记。

适应

在Vim中，可以通过不同的方式生成折叠（请参见参考资料:help fold-methods），并且取决于'filetype'缓冲区的大小。将上述行包含在折叠中的难度取决于此；与确认:setlocal foldmethod?。随着缩进折叠，有什么可以影响; 您必须切换到另一种方法。对于语法折叠，这将意味着修改语法定义，并且可能非常棘手。如果使用表达式，将会带来更多的运气，但这仍然意味着理解和改变逻辑。（文件类型插件作者不太可能提供配置来影响此设置。）

折线的语法高亮显示

不幸的是，这根本不可能。Vim始终Folded对整个折叠线使用高光组。您可以通过中的:highlight命令进行调整~/.vimrc，但是语法的个体差异将丢失。

Vim已经将折叠显示为一行。但是，在Vim的indent折叠中，所有具有相同缩进的行都包含在折叠中。因此，在屏幕截图中，您所指的“标题”行（例如，以开头的那一行collection_base_url）不在折叠内。

通过使用Vim可以实现类似于Atom的折叠方式foldexpr foldmethod：

" Finds the indent of a line. The indent of a blank line is the indent of the
" first non-blank line above it.
function! FindIndent(line_number, indent_width)
    " Regular expression for a "blank" line
    let regexp_blank = "^\s*$"

    let non_blank_line = a:line_number
    while non_blank_line > 0 && getline(non_blank_line) =~ regexp_blank
        let non_blank_line = non_blank_line - 1
    endwhile
    return indent(non_blank_line) / a:indent_width
endfunction

" 'foldexpr' for Atom-style indent folding
function! AtomStyleFolding(line_number)
    let indent_width = &shiftwidth

    " Find current indent
    let indent = FindIndent(a:line_number, indent_width)

    " Now find the indent of the next line
    let indent_below = FindIndent(a:line_number + 1, indent_width)

    " Calculate indent level
    if indent_below > indent
        return indent_below
    elseif indent_below < indent
        return "<" . indent
    else
        return indent
    endif
endfunction

set foldexpr=AtomStyleFolding(v:lnum)
set foldmethod=expr

这定义了一个fold表达式（请参阅参考资料:help fold-expr），如下所示：

• 对于紧缩行之前的行，它返回紧随其后的块的缩进。
• 对于缩进的行，它返回缩进。（除以shiftwidth，因此每个缩进级别将返回值增加1）
• 对于缩进行的末尾的行，它返回一个string "<N"，其中N设置为缩进。这告诉Vim 该行完成 N级折叠。

更新资料

@alxndr在评论中询问是否可以扩展它以将Ruby的outdented end包含在折叠中。您可以先" Calculate indent level用以下内容替换该部分：

if indent_below > indent
    return indent_below
elseif getline(a:line_number) =~ '^\s*end\s*$'
    return "<" . (indent + 1)
else
    return indent
endif

实际上，这不是最可靠的解决方案（例如，如果end语句位于分号后的同一行，它将失败。）您可以调整正则表达式和周围的代码以解决此问题，但是由于您现在处在解析文件实际语法的领域内，因此我认为在找到一个好的解决方案之前，事情可能会变得更加复杂。