如何在Vim中更改撤消粒度？

在某些时候，当我点击时，Vim会撤消整个单词u。

[i]typing some words[C-c][u]

会导致

typing some

但是，撤消粒度似乎已更改为一次删除一个字母。

[i]typing some words[C-c][u]

结果是

typing some word

我记得读过一些有关在实用Vim中自定义撤消粒度的信息，但是我不记得如何控制它。任何帮助表示赞赏！

手动中断撤消顺序

您可以使用手动在插入模式下中断撤消顺序<C-G>u。从帮助：

CTRL-G u        break undo sequence, start new change

例

iHello<C-G>u world!<Esc>u

这将使您留下文字

Hello

命令细目

i                           " Enter Insert mode
 Hello                      " Type 'Hello'
      <C-G>u                " Break the undo sequence
             world!         " Type ' world!'
                   <Esc>    " Return to Normal mode
                        u   " Undo

自动解决方案

细粒度的撤消级别控制

这是VimScript的一小段代码，用于<C-G>u在您开始删除文本时以及在删除后再次开始输入文本时创建撤消中断。

function! s:start_delete(key)
    let l:result = a:key
    if !s:deleting
        let l:result = "\<C-G>u".l:result
    endif
    let s:deleting = 1
    return l:result
endfunction

function! s:check_undo_break(char)
    if s:deleting
        let s:deleting = 0
        call feedkeys("\<BS>\<C-G>u".a:char, 'n')
    endif
endfunction

augroup smartundo
    autocmd!
    autocmd InsertEnter * let s:deleting = 0
    autocmd InsertCharPre * call s:check_undo_break(v:char)
augroup END

inoremap <expr> <BS> <SID>start_delete("\<BS>")
inoremap <expr> <C-W> <SID>start_delete("\<C-W>")
inoremap <expr> <C-U> <SID>start_delete("\<C-U>")

笔记

这将适用于<BS>，<C-W>（删除单词）和<C-U>（删除到行首）。如果在插入模式下有更多删除方法，可以通过inoremap在末尾添加其他呼叫来支持它们。