像Ctrl-A和Ctrl-X一样，但仅修改第一位

有没有一种方法可以增加/减少光标之后/下方的第一个数字，而不是整数。

我知道这不是vim的工作原理，但是有没有可以做到这一点的插件？我找不到它。

在编辑CSS或其他情况下，它非常有用。

鉴于：

▐margin: 10px

当我按时，CTRL-A我想看到：

▐margin: 20px

实际：

▐margin: 11px

这似乎工作得很好，并且<C-a>在9上使用（95变为105）或<C-x>在0上使用（105变为95）做的事情相当理智：

nnoremap g<C-a> :call search('\d', 'c')<CR>a <Esc>h<C-a>lxh
nnoremap g<C-x> :call search('\d', 'c')<CR>a <Esc>h<C-x>lxh

• 首先，我们搜索任何数字，search()其优点是无需重置@/。
• a <Esc>h -进入插入模式，在数字后添加一个空格，然后向左移动，使光标位于数字的顶部。
• 我们现在可以使用<C-a>或<C-x>。
• 我们lxh用来删除添加的空间。

我已将其映射到g<C-a>和g<C-x>，因此您仍然可以调用原始文件。

稍有不同的版本，它将仅在当前行中搜索数字（但如果当前行中没有数字，则将留下空白）：

nnoremap g<C-a> :call search('\d', 'c', line('.'))<CR>a <Esc>h<C-a>lxh
nnoremap g<C-x> :call search('\d', 'c', line('.'))<CR>a <Esc>h<C-x>lxh

这是另一个版本，它使用与以前相同的概念，但在数字前添加了空格。这将g<C-a>忽略该数字之前的任何munis符号（默认情况下，<C-a>on -42会将其“递增”到）-41。

它还接受一个计数，因此5g<C-a>会将数字增加5：

fun! Increment(dir, count)
    " No number on the current line
    if !search('\d', 'c', getline('.'))
        return
    endif

    " Store cursor position
    let l:save_pos = getpos('.')

    " Add spaces around the number
    s/\%#\d/ \0 /
    call setpos('.', l:save_pos)
    normal! l

    " Increment or decrement the number
    if a:dir == 'prev'
        execute "normal! " . repeat("\<C-x>"), a:count
    else
        execute "normal! " . repeat("\<C-a>", a:count)
    endif

    " Remove the spaces
    s/\v (\d{-})%#(\d) /\1\2/

    " Restore cursor position
    call setpos('.', l:save_pos)
endfun

nnoremap <silent> g<C-a> :<C-u>call Increment('next', v:count1)<CR>
nnoremap <silent> g<C-x> :<C-u>call Increment('prev', v:count1)<CR>

基本增量

这是执行操作的简单宏：

:nnoremap <leader>a m`lv$xh<c-a>p``
:nnoremap <leader>x m`lv$xh<c-x>p``

在正常模式下

• m` 标记您的位置
• l 向右移动一个字符
• v$x 切到行尾
• h 移回原始位置
• <c-a> 递增（或递减）
• p 粘贴你的伤口
• `` 回到你的标记

跳到下一个号码

如果要跳到下一个数字（或者在号码上时保持在当前位置），则需要一个功能来检查当前的光标字符并可能跳到下一个数字。

function! NextNum()
  let ch = getline(".")[col(".")-1]
  if ch !~ "[0-9]"
    execute "normal! /[0-9]\<cr>"
  endif
endfunction

nnoremap <leader>a :call NextNum()<cr>m`lv$xh<c-a>p``
nnoremap <leader>x :call NextNum()<cr>m`lv$xh<c-x>p``

NextNum获取光标下的字符，检查其是否为数字，如果不是，则搜索下一个数字。之后，其余部分相同。如果您希望映射不同，则只需将更改为所需的值nnoremap <leader>a即可nnoremap <c-a>。

忽略负数和大于9的数字

如果只想循环显示数字而不让它们充当带符号的整数，则以下函数将在0和9处递增，递减和翻转。

function! NextNum()
  let ch = getline(".")[col(".")-1]
  if ch !~ "[0-9]"
    execute "normal! /[0-9]\<cr>"
  endif
endfunction

function! IncDec(val, dec)
  if a:dec
    if a:val == 0
      return 9
    else
      return a:val - 1
    endif
  else
    if a:val == 9
      return 0
    else
      return a:val + 1
    endif
  endif
endfunction

function! DoMath(dec)
  call NextNum()
  normal! x
  let @" = IncDec(@", a:dec)
  normal! P
endfunction

nnoremap <leader>a :call DoMath(0)<cr>
nnoremap <leader>x :call DoMath(1)<cr>

现在，当您打开8并键入时，<leader>a您会得到9。老毛病又犯了导致0。如果按<leader>x，0您将得到9。负数也一样。这些功能剪切单个字符，递增，递减或翻转，然后粘贴到位。

这是我使用替代表达式编写的版本：

map <c-a> :s/\d/\=submatch(0) < 9 ? submatch(0) + 1 : submatch(0)/<CR>
map <c-x> :s/\d/\=submatch(0) > 0 ? submatch(0) - 1 : submatch(0)/<CR>

每个人仅查找行中的第一个数字字符，并且分别在[0-8]或[1-9]范围内加或减。它具有三个问题：

1. 它主要是文本操作，并且仅查看第一个字符，因此它不知道数字是否为负数。这是可以解决的，但是我喜欢当前的行为。
2. 它掩盖了搜索寄存器："/，如果启用了hlsearch，则当您使用hlsearch时，当前缓冲区中的所有数字都将突出显示。您可以:noh<CR>在上述每个map命令后附加以停止突出显示，但是我不知道如何很好地阻止寄存器被破坏。
3. 它适用于行的第一个数字，而不是光标之后的第一个数字。

另外，如果是我，则将上述内容映射到<leader>a和<leader>x，而不是CTRL-A/X。这样，您就可以同时使用两种行为。<leader>默认情况下是反斜杠键（\）。