如何在gVim中更改字体大小？

是否可以使用本机命令更改gVim中字体的大小？

如果没有，可以使用什么脚本快速完成？

在中设置guifont选项.gvimrc。请参阅:help guifont和:help setting-guifont。

具体来说，您可以执行以下操作：set guifont=Consolas:h11在Windows的gvim中使用11点Consolas。您可以使用其他一些选项（每个选项都用分隔:），例如:b粗体字，尽管其中某些选项仅在某些平台上可用。

如所示:h，设置字体大小的选项可能是最有用的，并且与您要求的更改字体大小特别相关。

如果只想更改正在运行的GVim实例中的字体大小，请键入：

:set guifont=*

应该会弹出一个窗口，让您设置字体大小，并根据需要选择新字体。然后，您可以要求Vim打印您需要添加到行中的行，~/.gvimrc以使更改永久生效：

:set guifont?

在状态行中生成类似以下内容的内容：

guifont=Hasklig-Light:h16

将其添加set到您的前缀~/.gvimrc以继续。

我的.vimrc中包含以下内容，可在不更改字体的情况下快速更改字体大小。在Windows和GTK上均可使用。我还没有测试其他GUI。我确定我最初是从其他人那里复制它的，但是它已经存在于我的rc文件中了很长时间，我不记得它是从哪里来的。

if has("unix")
    function! FontSizePlus ()
      let l:gf_size_whole = matchstr(&guifont, '\( \)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole + 1
      let l:new_font_size = ' '.l:gf_size_whole
      let &guifont = substitute(&guifont, ' \d\+$', l:new_font_size, '')
    endfunction

    function! FontSizeMinus ()
      let l:gf_size_whole = matchstr(&guifont, '\( \)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole - 1
      let l:new_font_size = ' '.l:gf_size_whole
      let &guifont = substitute(&guifont, ' \d\+$', l:new_font_size, '')
    endfunction
else
    function! FontSizePlus ()
      let l:gf_size_whole = matchstr(&guifont, '\(:h\)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole + 1
      let l:new_font_size = ':h'.l:gf_size_whole
      let &guifont = substitute(&guifont, ':h\d\+$', l:new_font_size, '')
    endfunction

    function! FontSizeMinus ()
      let l:gf_size_whole = matchstr(&guifont, '\(:h\)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole - 1
      let l:new_font_size = ':h'.l:gf_size_whole
      let &guifont = substitute(&guifont, ':h\d\+$', l:new_font_size, '')
    endfunction
endif


if has("gui_running")
    nmap <S-F12> :call FontSizeMinus()<CR>
    nmap <F12> :call FontSizePlus()<CR>
endif

显然，字体设置的编写方式与平台有关。对我有用的东西（MX Linux 17中的gvim（具有XFCE桌面的基于Debian的Linux发行版））：

• 使用以下命令确定打开的gvim实例中的当前字体设置 : set guifont?

例： guifont=DejaVu Sans Mono 12

• 使用该信息编写的设置（修改为所需的尺寸）的~/.gvimrc文件，逃避的空间用反斜杠，并没有使用:大小之前。

例： set guifont=DejaVu\ Sans\ Mono\ 18

• 保存~/.gvimrc文件后，新的gvim实例应使用新的所需大小。

这两个答案帮助我：

• https://askubuntu.com/a/3532/129295
• https://stackoverflow.com/a/21894257/1878788

以及对此的评论：

• https://vi.stackexchange.com/a/3094/13481

根据Drew的回答，此设置对我来说效果更好。

它使用或（假设您是领导者）来增大或减小字体大小，并使用来循环浏览预定义的字体。我经常在这些字体之间进行交换，这取决于我使用的是源代码还是文本。\+\-\cot

let g:fnt_types = ['SourceCode\ Pro', 'monofur' ]
let g:fnt_sizes = [ 10, 13 ]


let g:fnt_index = 0
let g:fnt_size  = g:fnt_sizes[g:fnt_index]

function! CycleFont()
  let g:fnt_index = (g:fnt_index + 1) % len(g:fnt_types)
  let g:fnt_size  = g:fnt_sizes[g:fnt_index]
  call ResetFont()
endfunction

function! ResetFont ()
  if has('gui_running')
    exe ':set guifont=' . g:fnt_types[g:fnt_index] . '\ ' . string(g:fnt_size)
  endif
endfunction

call ResetFont()

function! FontSizePlus ()
  let g:fnt_size = g:fnt_size + 0.5
  call ResetFont()
endfunction

function! FontSizeMinus ()
  let g:fnt_size = g:fnt_size - 0.5
  call ResetFont()
endfunction

nnoremap <leader>+ :call FontSizePlus()<cr>
nnoremap <leader>- :call FontSizeMinus()<cr>
nnoremap cot :call CycleFont()<cr>

您可以尝试使用此插件：vim-fontzoom。

map <m-o> :Fontzoom!<cr>
map <m--> <Plug>(fontzoom-smaller)
map <m-=> <Plug>(fontzoom-larger)