是否有折叠vimrc文件的最佳实践

我最近意识到我vimrc现在已经超过400行（IMO太多了，我会尽量减少它），并且为了使其更易于浏览，阅读和编​​辑，我决定研究一下vim中的可折叠概念（我不熟悉）。

• 我尝试将folding方法设置为，indent但是我不喜欢结果（这太混乱了，主要是因为我的很大一部分vimrc都没有真正缩进）。
• 我也尝试设置foldmethod为expr，syntax但无法正确折叠任何东西。
• 在这里，diff用作折叠方法似乎无关紧要。（或者如果我不明白如何使用它）
• 因此，marker由于我在文件中发现了“ "{{{和” "}}}标记，因此目前我使用的方法并不完全令我满意。

因此，我想知道是否存在有关正确折叠的最佳实践或通用准则vimrc。

注意1：众所周知，SO不是论坛，也不是收集个人意见，这也不是我想要的：当然，我猜有些人有他们的偏好，但我想知道为什么使用例如，标记比使用缩进可提高可读性。

注2：我的主要目标也是使自己vimrc尽可能清晰，因此，如果存在其他最佳做法来创造一个好的，vimrc我对此很好奇。

编辑1：我应该明确指出，我的vimrc内容已经细分为（主要是

• 常规选项
• 插件（每个插件及其配置包含一个小节）
• 映射
• 导航（也包含小节）
• 颜色
• 等等...

正是这种结构让我想到了折叠：我觉得能够只在特定点上输出我感兴趣的部分非常方便。

编辑2：vimrc在几个文件中提及细分的答案是有效的，但出于个人喜好，我宁愿使用折叠，因为我认为在包含我的dotfile的git repo中仅维护一个文件会更容易。那只是个人喜好，我知道也可以使用这种方法，但是我更喜欢使用折叠。

我在表格的底部有以下vimrc模式行，这些行是从表格的作者Godlygeek复制而来的：

"" vim:fdm=expr:fdl=0
"" vim:fde=getline(v\:lnum)=~'^""'?'>'.(matchend(getline(v\:lnum),'""*')-2)\:'='

这将使任何以2+ "' 开头的行都折叠。越多"，折痕越深。这使您可以根据需要细分部分。

最好先在自己的类别中定义自己的类别.vimrc（例如带有子列表和子子列表的列表），然后将所有插件/设置/功能添加到相应的类别中。结合定制折叠功能，可以很好地发挥作用：

上面的示例显示了可能对我的结构有所帮助的类别.vimrc。它使用以下定制的折叠设置：

""""""""""""""""""""""""
"  THIS IS A CATEGORY  "
""""""""""""""""""""""""
"" Autofolding .vimrc
" see http://vimcasts.org/episodes/writing-a-custom-fold-expression/
""" defines a foldlevel for each line of code
function! VimFolds(lnum)
  let s:thisline = getline(a:lnum)
  if match(s:thisline, '^"" ') >= 0
    return '>2'
  endif
  if match(s:thisline, '^""" ') >= 0
    return '>3'
  endif
  let s:two_following_lines = 0
  if line(a:lnum) + 2 <= line('$')
    let s:line_1_after = getline(a:lnum+1)
    let s:line_2_after = getline(a:lnum+2)
    let s:two_following_lines = 1
  endif
  if !s:two_following_lines
      return '='
    endif
  else
    if (match(s:thisline, '^"""""') >= 0) &&
       \ (match(s:line_1_after, '^"  ') >= 0) &&
       \ (match(s:line_2_after, '^""""') >= 0)
      return '>1'
    else
      return '='
    endif
  endif
endfunction

""" defines a foldtext
function! VimFoldText()
  " handle special case of normal comment first
  let s:info = '('.string(v:foldend-v:foldstart).' l)'
  if v:foldlevel == 1
    let s:line = ' ◇ '.getline(v:foldstart+1)[3:-2]
  elseif v:foldlevel == 2
    let s:line = '   ●  '.getline(v:foldstart)[3:]
  elseif v:foldlevel == 3
    let s:line = '     ▪ '.getline(v:foldstart)[4:]
  endif
  if strwidth(s:line) > 80 - len(s:info) - 3
    return s:line[:79-len(s:info)-3+len(s:line)-strwidth(s:line)].'...'.s:info
  else
    return s:line.repeat(' ', 80 - strwidth(s:line) - len(s:info)).s:info
  endif
endfunction

""" set foldsettings automatically for vim files
augroup fold_vimrc
  autocmd!
  autocmd FileType vim 
                   \ setlocal foldmethod=expr |
                   \ setlocal foldexpr=VimFolds(v:lnum) |
                   \ setlocal foldtext=VimFoldText() |
     "              \ set foldcolumn=2 foldminlines=2
augroup END

要定义自己的类别和子类别，请使用以下语法：

""""""""""""""
"  Category  "
""""""""""""""
"" Subcategory
""" Subsubcategory
" Just a comment, gets ignored no matter where

如果您使用vim片段（例如，使用UltiSnips），则可以非常容易地创建顶级类别：只需展开vim片段提供的box或bbox片段（编写box或bbox按扩展触发器）。

要通过两次按空格来更快地打开和关闭折叠，请执行以下操作：

let mapleader = "\<space>"
" Toggle folds
nnoremap <silent> <leader><Space> @=(foldlevel('.')?'za':"\<Space>")<CR>
vnoremap <leader><space> zf

这样，您.vimrc就可以轻松地导航并具有良好的结构。

我将我的主文件vimrc用作指向其他几个分类文件的链接，并按需采购每个文件，例如，一个文件中的Vim选项，另一个文件中的插件设置。

"--- Vim Options
source ~/.vim/config/vim_options.vim

"--- Here Be Functions!
" (need to be sourced before stuff that uses 'em)
runtime! functions/*.vim

"--- Key Mapping
source ~/.vim/config/key_mapping.vim

"--- Folding
source ~/.vim/config/folding.vim

"--- Autocmds
source ~/.vim/config/autocmds.vim

"--- We Are Plugged In!
source ~/.vim/config/plugins.vim

" vim: ft=vim fdm=marker

作为对OP问题的更直接答案，我确实使用了标记方法，但是在大多数情况下，它以右侧隔开间隔，并且类别比单个类别多。我分别做每个插件。

您可以说“最佳实践”主要是一个见解，:)但是有两种方法（1）显而易见，并且（2）可以应用于所有配置文件，不仅限于Vim：按逻辑部分折叠和小节（或者更深的部分，如果您觉得很勇敢），并将您的配置分成几个较小的文件并对其进行:source-ing操作。

我个人更喜欢折叠，因为它使事情更容易访问，同时仍然给我一些层次。autocmd在最内层折叠功能和s也是一个好主意，因为它们构成了“自然的”逻辑单元。 marker对于所有这一切，折叠是最有意义的，因为逻辑层次结构不一定反映到缩进级别或语法突出显示中。我还增加了foldcolumn，这给了我一个视觉上的提示：

# vim: filetype=vim foldmethod=marker foldlevel=0 foldcolumn=3

附带说明一下，此foldtext功能（IIRC的Drew Neil对类似功能的修改）对我来说比默认值有意义：

function! MyFoldText()
    let line = getline(v:foldstart)

    let nucolwidth = &foldcolumn + &number * &numberwidth
    let windowwidth = winwidth(0) - nucolwidth - 3
    let foldedlinecount = v:foldend - v:foldstart

    " expand tabs into spaces
    let chunks = split(line, "\t", 1)
    let line = join(map(chunks[:-2], 'v:val . repeat(" ", &tabstop - strwidth(v:val) % &tabstop)'), '') . chunks[-1]

    let line = strpart(line, 0, windowwidth - 2 - len(foldedlinecount))
    let fillcharcount = windowwidth - len(line) - len(foldedlinecount) - 1
    return line . '...' . repeat(' ', fillcharcount) . foldedlinecount . ' '
endfunction
set foldtext=MyFoldText()

使用另一种方法（拆分文件），主要问题是查找内容并从一个文件切换到另一个文件。解决这两个问题的一种很好的方法是使用CtrlSF，CtrlP或类似的插件。但是无论如何，您可能已经在使用其中之一。

基本最佳实践：

• 分为几个部分：

  • 外挂程式
  • 设定值
  • 重新绑定

• 评论每个部分/重新绑定

• （备份您.vimrc或_vimrc在Github上）

只是我个人的喜好。也许没有太多帮助。

受@PeterRincker的答案启发，我精心设计了以下内容以使用ATX样式标头。将其添加到您的末尾.vimrc

"# Folding

" Fold with ATX style headers - "# is H1, "## is H2, and so on
" vim:fdm=expr:fdl=0
" vim:fde=getline(v\:lnum)=~'^"#'?'>'.(matchend(getline(v\:lnum),'"#*')-1)\:'='

如果您拥有像我这样的大型功能，则可以使用此功能折叠功能：

fun! MyFoldLevel(linenum)
    if ! exists('w:nextline')
        let w:nextline = 0
        let w:insideafun = 0
    endif

    if w:nextline == 1
        let w:nextline = 0
        let w:insideafun = 0
    endif

    let l:line = getline(a:linenum)

    if l:line =~# '^[[:space:]]*fun'
        let w:insideafun = 1
        return '>1'
    elseif l:line =~# '^[[:space:]]*endf'
        let w:nextline = 1
        return '<1'
    endif

    if w:insideafun == 1
        return 1
    else
        return 0
    endif
endfun

并将这个modeline添加到您的vimrc中：

" vim:fde=MyFoldLevel(v\:lnum):fdm=expr:

扩展了@Peter Rincker和@ go2null的想法。如果不想在Vim modeline中设置折叠选项。您可以使用以下autocmd来设置折叠方法和折叠表达式。

augroup vim_folding
    autocmd!
    autocmd FileType vim set foldmethod=expr foldlevel=0
    " note that double quote in foldexpr has to be escaped with backslash
    autocmd FileType vim set foldexpr=getline(v:lnum)=~'^\"#'?'>'.(matchend(getline(v:lnum),'\"#*')-1):'='
augroup END

我做了一些小的修改，以使原始答案能够像常规的vim命令一样工作（无需转义冒号，但需要转义双引号）。

如果您不喜欢长foldexpr字符串，我们可以为此定义一个函数：

function! VimFolds(lnum)
    let s:cur_line = getline(a:lnum)

    if s:cur_line =~ '^"#'
        return '>' . (matchend(s:cur_line, '"#*')-1)
    else
        return '='
    endif

endfunction

然后将autocmd行替换foldexpr为

autocmd FileType vim set foldexpr=VimFolds(v:lnum)