我可以重复上一个UI命令吗？

我知道我可以.用来重复上一个编辑命令。

有没有办法重复上一个UI操作命令？例如，我可以写成10<C-W>-将窗口缩小十行。如果我想进一步缩小命令范围，可以按⟨ 一些键 easily轻松地重复此命令，将是很好的选择。

点命令.之所以有效，是因为Vim会“保持跟踪”更改缓冲区内容的命令。如果运行:echo b:changedtick，则每次对当前缓冲区的更改都会使它递增。

但是Vim不会“跟踪”非编辑命令。因此，不，您的要求无法完成。

在vim中，默认情况下无法执行此操作，因为vim不会跟踪先前执行的wincmd。但是，可以通过一些巧妙的映射来做到这一点：

function! s:Wincmd(count, key)
    " If count is not zero, use the original count.  If otherwise, don't
    " include a count.
    let if_count = a:count ? a:count : ""
    " This builds a wincmd from the given key, and saves it so
    " it can be repeated.
    let g:last_wincmd = "wincmd " . nr2char(a:key)
    " Execute the built wincmd
    execute if_count . g:last_wincmd
endfunction

function! s:WincmdRepeat(count)
    " If no wincmd has been executed yet, don't do anything
    if !exists('g:last_wincmd') | return | endif
    " If a count is given, repeat the last wincmd that amount of times.
    " If otherwise, just repeat once.
    let if_count = a:count ? a:count : ""
    execute if_count . g:last_wincmd
endfunction

" Overwrite the default <C-w> mapping so that the last wincmd can be kept
" track of.  The getchar function is what captures the key pressed
" directly afterwards.  The <C-u> is to remove any cmdline range that vim
" automatically inserted.
nnoremap <silent> <C-w> :<C-u>call <SID>Wincmd(v:count, getchar())<CR>

" This just calls the function which repeats the previous wincmd.  It
" does accept a count, which is the number of times it should repeat the
" previous wincmd.  You can also replace Q with whatever key you want. 
nnoremap <silent> Q :<C-u> call <SID>WincmdRepeat(v:count)<CR>

请注意，如果有任何使用的映射，<C-w>则只有在它们不相同时才可以重复nore。使用发出的任何wincmds :wincmd将不会重复。另外，不能执行任何包含多个字符的wincmds （例如<C-w>gf）。

相关帮助主题

• :help v:count
• :help getchar()
• :help nr2char()
• :help expr1
• :help :wincmd
• :help :execute
• :help :for
• :help :map-<silent>
• :help c_CTRL-U
• :help <SID>

该子模式插件可以帮助这一点。您可以输入来定义输入的“子模式” <C-W>-，其中您已经定义了-（也许是+）继续调整窗口的大小。

还有另一个名为repmo.vim的插件（“ repeat motions”），可以执行您想要的操作。

但是您需要指定要重复的动作（或一般动作）。我的当前配置如下：

let g:repmo_mapmotions = "j|k h|l zh|zl g;|g, <C-w>w|<C-w>W"
let g:repmo_mapmotions .= " <C-w>+|<C-w>- <C-w>>|<C-w><"
let g:repmo_key = ";" 
let g:repmo_revkey = "," 

因此，完成后，5 CTRL-W +我可以;重复多次。

该插件通过为指定的每个键创建映射来工作。

使用f或时t，;和,映射将被清除回其默认行为。

我发现映射对于g;返回先前的编辑点特别有用。 g; ; ; ;