通过交织线合并块

有没有一种专门的方法可以通过插入行来合并两个文本块，就像从下面这样传递：

a1
a2
a3
a4
  b1
  b2
  b3
  b4

对此：

a1
  b1
a2
  b2
a3
  b3
a4
  b4

在几个命令？

编辑：我真的很喜欢佐藤桂的解决方案，这是我如何实现它：

function! Interleave()
    " retrieve last selected area position and size
    let start = line(".")
    execute "normal! gvo\<esc>"
    let end = line(".")
    let [start, end] = sort([start, end], "n")
    let size = (end - start + 1) / 2
    " and interleave!
    for i in range(size - 1)
        execute (start + size + i). 'm' .(start + 2 * i)
    endfor
endfunction

" Select your two contiguous, same-sized blocks, and use it to Interleave ;)
vnoremap <pickYourMap> <esc>:call Interleave()<CR>

没有专门的方法可以做到这一点（据我所知），但是是的，可以使用一些命令来完成：

function! Interleave(start, end, where)
    if a:start < a:where
        for i in range(0, a:end - a:start)
            execute a:start . 'm' . (a:where + i)
        endfor
    else
        for i in range(a:end - a:start, 0, -1)
            execute a:end . 'm' . (a:where + i)
        endfor
    endif
endfunction

您可以使用运行它:call Interleave(5, 8, 1)。第一个参数是要移动的第一行，第二个参数是最后一行，第三个参数是要移动它们的位置。您可能希望打开行号以查看自己在做什么（:set number）。

这假定块不重叠。查看:help :move并:help range()了解该功能的工作原理。

可能有更好的方法来拾取两个块。有一个左右浮动的插件，可以让您交换两个块。我不记得插件的名称，但是作者（也许是著名的Dr. Chip？）比我投入了更多的心思来寻找接口。:)

这是另一种选择：

:g/^a/+4t .
:+,+5d 

首先将下面4行以下的行复制到当前行（:h :t）之后，然后删除连续的b行（:h :d）

更好的命令是：

 :g/^a//^\s*b/m .

这意味着，对于以查找开头的每一行，请查找以“ b”开头的下一行并将其移至当前行下方。

如果您想对宏和标记有一点乐趣，可以尝试如下操作：

• 首先做了个记号（这里a）对包含该行a1与ma

• 转到包含的行b1并标记为mb

• 开始使用以下命令在所需的寄存器（此处为寄存器q）中记录宏qq

• 在您的宏中插入以下内容： ddmb'apjma'b

• 停止记录宏 q

• 根据需要播放多次，X@q其中X播放的时间是多少。

详细说明宏：

dd mb 'a p j ma 'b
 |  |  | | |    |
 |  |  | | |    go back to line marked `b`
 |  |  | | |
 |  |  | | move of one line and replace the mark `a`
 |  |  | insert the deleted line under the line marked `a`
 |  |  go to line marked `a`
 |  mark the future line to move with `b`
 delete the line to move

编辑正如lago-lito在评论中提到的那样，此方法将覆盖标记和缓冲区。

• 对于商标，我认为这不是一个真正的问题：我很少在缓冲区中使用所有26个商标，而且我认为大多数时候都会找到2个免费商标。

• 对于缓冲区，可以将其保存在一个临时变量中：在记录宏之前，先使用它:let saveReg=getreg('"')来保存寄存器，并在完成操作后使用:call setreg('"', saveReg)来使寄存器回到其先前状态。

无论如何，我必须承认该解决方案只是一种快速的解决方法，并且不是最佳解决方案：我认为Christan的答案是最好的，应该接受，因为它不会弄乱缓冲区和标记，不会迫使用户创建功能，并显示全局命令的功能。

我刚刚看到了另一个类似的问题，解决方案包括：

跳到中间加一：

Mj

并运行：

:,$g/./exe 'm' 2*line('.')-line('$')-1