列出已知的文件类型

如何获得vim当前知道的文件类型名称列表？

我希望能够做到这一点，以便在vim无法自动检测到文件类型时，我可以尝试一些vim知道的文件类型，这些文件类型可能相似，并查看它们是否提供合理的语法突出显示。

我知道处理文件类型的vimscript文件是按惯例放在ftplugin目录中的，但它们不一定是必需的（我不确定，但我不认为ftplugin目录中的vimscript文件是特殊的），所以我只想询问vim它知道什么文件类型，而不管它如何了解它们。

简单的解决方案

键入:setfiletype （后跟一个空格），然后按Ctrl-d。

有关:help cmdline-completion更多信息，请参见vim的命令行。

复杂的解决方案

该解决方案使用该'runtimepath'选项来获取所有可用的语法目录，然后在这些目录中删除其扩展名的情况下获取vimscript文件的列表。这可能不是最安全的方法，因此欢迎进行改进：

function! GetFiletypes()
    " Get a list of all the runtime directories by taking the value of that
    " option and splitting it using a comma as the separator.
    let rtps = split(&runtimepath, ",")
    " This will be the list of filetypes that the function returns
    let filetypes = []

    " Loop through each individual item in the list of runtime paths
    for rtp in rtps
        let syntax_dir = rtp . "/syntax"
        " Check to see if there is a syntax directory in this runtimepath.
        if (isdirectory(syntax_dir))
            " Loop through each vimscript file in the syntax directory
            for syntax_file in split(glob(syntax_dir . "/*.vim"), "\n")
                " Add this file to the filetypes list with its everything
                " except its name removed.
                call add(filetypes, fnamemodify(syntax_file, ":t:r"))
            endfor
        endif
    endfor

    " This removes any duplicates and returns the resulting list.
    " NOTE: This might not be the best way to do this, suggestions are welcome.
    return uniq(sort(filetypes))
endfunction

然后，您可以以任何所需的方式使用此功能，例如打印列表中的所有值。您可以这样完成：

for f in GetFiletypes() | echo f | endfor

注意，这可能可以压缩很多，就像为了可读性一样。我不会在这里解释所有使用的功能和命令，但是这里是它们的所有帮助页面：

• :help 'runtimepath'
• :help :let
• :help :let-&
• :help split()
• :help :for
• :help expr-.
• :help :if
• :help isdirectory()
• :help glob()
• :help fnamemodify()
• :help add()
• :help uniq()
• :help sort()

如果您的vim版本足够新（v7.4.2011 +），则可以使用我们现在可以用来帮助定义手动自动完成功能的功能来请求已知文件类型： getcompletion()

:echo getcompletion('', 'filetype')

如果您希望将列表限制为以开头的文件类型'c'，请致电

:echo getcompletion('c', 'filetype')

等等。

注意：与解析中的文件名和目录名的$VIMRUNTIME/{syntax,filetype}/解决方案不同，此解决方案'runtimepath'也会进行分析。据我了解，它看不到使用set ft=foobar或在自动命令之后动态定义/注册的新文件类型。

您还可以通过运行以下2个命令在终端中打印所有文件类型：

1。

cd $(vim -e -T dumb --cmd 'exe "set t_cm=\<C-M>"|echo $VIMRUNTIME|quit' | tr -d '\015')

2。

cat <(ls -1 ftplugin/*.vim) <(ls -1 syntax/*.vim) | tr '\n' '\0' | xargs -0 -n 1 basename | sort | uniq | cut -f 1 -d '.'

第一个命令只是导航到您的vim运行时路径（对我来说是/ usr / share / vim / vim80）。

第二条命令列出了vim存储文件类型定义的两个文件夹中的所有文件类型名称。

更新资料

建议对muru的两个命令进行以下改进：

1。

cd $(vim -Nesc '!echo $VIMRUNTIME' -c qa)

2。

find syntax ftplugin -iname '*.vim' -exec basename -s .vim {} + | sort -u