我有一个链接到表格的Google表格，该表格使用相同的表格并进行了3次编辑，收集了来自同一主题上三个不同人的回复。这将创建一个包含三列的表格，说明这三个人的位置。

我需要生成一个视图/查询，该视图/查询将这三列放置在彼此的“下方”，而不是彼此相邻。在数据库中，我会做类似下面的查询的操作，我将我的“工作表”命名为tblMain，并说明了相关的四列（我还需要主题ID）。

tblMain：

ID        RALocation        RBLocation        RCLocation

查询：

Select ID, RALocation as Location, 'RA' as Role from tblMain
Union
Select ID, RBLocation as Location, 'RB' as Role from tblMain
Union
Select ID, RCLocation as Location, 'RC' as Role from tblMain

有人知道Google表格中是否有这样做的方法吗？我不介意构建多个表，然后在最后将它们合并，但是我对如何执行此操作有些困惑。

我提供两个版本，具体取决于是否应保留空白单元格。基本思想是相同的：

1. 选择表中不包含的字符（例如，可通过访问的奇异Unicode字符CHAR）。
2. 在JOIN命令中为三列中的每一列使用它。
3. 连接结果，在两者之间添加字符。
4. SPLIT 由相同字符连接的字符串。
5. TRANSPOSE 结果。

例如：

=TRANSPOSE( SPLIT( JOIN(CHAR(57344),A1:A) &CHAR(57344)& JOIN(CHAR(57344),B1:B) &CHAR(57344)& JOIN(CHAR(57344),C1:C), CHAR(57344) ) )

在哪里进行联接/拆分，我选择了一个字符CHAR(57344)，该字符指定供私人使用，因此不应出现在任何有效输入中。

上面的公式删除了空白条目，因为这是这样SPLIT做的。如果您的数据没有空白，这可能很方便：省去了跟踪数据最后一行的位置的麻烦。但是其他时候，应该保留空白。

为了保留空格，我遵循Jacob Jan Tuinstra的回答，只是我使用了另一个私有的Unicode而不是空格（谁知道，也许您有一些仅包含空格的单元格，并且您想保留这些空格）。这涉及两个额外的步骤：在像以前一样加入所有内容之后，我使用SUBSTITUTE替换CHAR(57344)为CHAR(57344)&CHAR(57345)，然后像以前一样拆分，然后替换CHAR(57345)为空字符串。

=TRANSPOSE( ARRAYFORMULA(SUBSTITUTE( SPLIT( SUBSTITUTE(...joins... , CHAR(57344),CHAR(57344)&CHAR(57345)), CHAR(57344) ), CHAR(57345), "")))

完整结果如下所示（注意，现在我指定数据的最后一行在哪里）：

=TRANSPOSE( ARRAYFORMULA(SUBSTITUTE( SPLIT( SUBSTITUTE(JOIN(CHAR(57344),A1:A9) &CHAR(57344)& JOIN(CHAR(57344),B1:B9) &CHAR(57344)& JOIN(CHAR(57344),C1:C9), CHAR(57344),CHAR(57344)&CHAR(57345)), CHAR(57344) ), CHAR(57345), "" )))

还有一个警告：Google表格中的字符串长度不能超过50000个字符。如果您的数据太大而无法使用基于字符串的方法，请使用脚本（这是一个很好的起点）。

如今，使用以下公式可以很容易地在Google Spreadsheet中建立联盟：

={'Sheet1'!A2:A;'Sheet2'!A2:A;'Sheet3'!A2:A}

在Google文档帮助中查看更多信息：在Google表格中使用数组

简短答案

Google表格是一种非常强大的工具，可以通过多种方法来实现类似于UNION-SELECT的结果。

备择方案

嵌入式阵列

使用SPLIT-TRANSPOSE-JOIN-CHAR方式的另一种方法是使用嵌入式数组。这种方法的一个优点是它不需要构造/解构字符串，因此，字符数的限制是无关紧要的。

筛选

对于需要过滤以具有类似UNION-SELECT行为的情况，以上内容可以与FILTER（）结合使用。例

={Filter(A1:B2, B1:B2=2);Filter(D1:E2, E1:E2=6);Filter(G1:H2, H1:H2=12)}

也可以与QUERY（）结合使用，但其结果包括标题行。要了解如何清除标题，请参阅Google Spreadsheets查询结果中的清除行。

如何创建一列值

使用TRANSPOSE-SPLIT-REPT创建一列值。

={Transpose(Split(REPT("RA,",6),","))}

也可以使用QUERY（）创建一列值，但是删除标题行会使公式更复杂。仅当字符串长度限制导致问题时才使用它。

使用嵌入式阵列和TRANSPOSE-SPLIT-REPT的解决方案

假定范围tblMain是A1：D7，其中A1：D1是表头，数据在A2：D7中。

={{"ID";A2:A7;A2:A7;A2:A7},
{"Location";B2:B7;C2:C7;D2:D7},{"Role";
Transpose(Split(REPT("RA,",6),","));
Transpose(Split(REPT("RB,",6),","));
Transpose(Split(REPT("RC,",6),","))}}

参考文献

附加谷歌电子表格数组-代码日志