在Finder中创建新的（.txt）文件-键盘快捷键

我想知道是否可以设置键盘快捷键来在Finder中创建新文件。例如，默认情况下，您可以使用CMD+ Shift+ 创建一个新文件夹N。是否有键盘快捷键来创建新的文本文件？我是一名程序员，所以这将非常有用

我也会对使用键盘快捷键创建其他文件类型感兴趣。

我曾尝试使用自动器，但发现它很混乱，而且不确定如何将键盘快捷方式连接到自动器。

好吧，这里您使用了AppleScript。

首先，创建AppleScript：

1. 打开自动器
2. 创建快速动作
3. 将输入设置为无输入
4. 将“ 运行AppleScript工作流”元素拖放到灰色空间。
5. 从下面将代码粘贴到AppleScript中
6. 将工作流程另存为“ 创建新文件”
   如果激活了iCloud Drive，请确保将文件保存Library/Services/在主文件夹中。

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

要将其添加为快捷方式：

• 转到系统偏好设置->键盘->快捷方式->服务
• 向下滚动，直到找到“服务创建新文件”
• 通过单击右侧的none为其分配快捷方式，该快捷方式将变为Add Shortcut。
  单击按钮，然后键入您要使用的快捷方式。
  我用⌘ Command+ ⌥ Option+N

我创建了一个与@YoshiBotX十分相似的AppleScript，但有一些改进。

这个想法是创建一个Automator工作流程并使用以下步骤为其分配快捷方式：

• 打开Automator并创建服务；
• 将输入设置为无输入，将应用程序设置为Finder.app ;
• 将运行AppleScript工作流元素拖放到灰色空间；
• 将这个AppleScript的内容放在文本框中；
• 用合理的名称保存工作流程（例如New File）；
• 转到设置->键盘->快捷方式->服务，并为其分配快捷方式。

现在，让我们展示一下AppleScript：

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

为了方便起见，我将这个AppleScript放在GitHub Gist中。

您可以自己创建一个Automator Service，这很简单。然后，您可以为其分配键盘快捷键，这样就无需通过“服务”菜单激活该服务（您仍然可以执行该操作）。

打开Automator，然后选择“服务”作为新文档的类型。

将服务设置为在Finder.app中不接收任何输入，然后将“新建TextEdit文档”操作添加到工作流中。

保存服务，然后打开“系统偏好设置”→“键盘”→“快捷方式”→“服务”，您将在“常规”下找到该服务，并在保存时为其指定了名称。

通过选择服务，然后单击“添加快捷方式”，将键盘快捷方式添加到服务。

如果已经使用了快捷方式，在这里您可能会遇到一些问题。因此，请发挥创意，使它适合您。

您还可以为脚本分配快捷方式，如下所示：

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

插入位置是最前面的Finder窗口或桌面的目标。

打开终端并输入

touch filename

要么

> filename

这是我去年发布的帖子的转贴。我在以下方面有很好的经验。

您可以下载和安装两个有用的实用程序，使您可以在使用Finder查看的当前打开的文件夹中创建新的文本文件（或RTF文件）。

这些实用程序称为NewTextFileHere和NewRTFHere，可以从以下位置下载

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

然后，可以将所有这些应用程序的图标包含在所有Finder窗口中。

我一直在寻找的是Richard Fuhr。谢谢你

注意：NewTextFileHere的URL链接似乎加载到空白页面。但是我进行了搜索，并在此处找到了该应用程序：http : //mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

另一种选择是，如果您已经拥有BetterTouchTools（它曾经是一个免费应用，现在它具有30天试用期的“ 按需付费”模型），则可以找到执行此操作的"Utility Actions > Create New File in Current Folder"确切方法弹出窗口，让您选择名称。分配所需的快捷方式（我选择了Option + Shift + N），一切就很好了。

如果您使用的是MacVim，下面有一个选项Finder -> Services可以创建一个新的vim缓冲区：

我已经映射了该短切ShiftcmdM在System Preferences -> Keyboard -> Shortcuts：