在iTunes中使用右键单击播放文件夹

这个答案来播放文件夹右键用VLC介绍了如何打一个文件夹内的所有音轨可以使用VLC时完成。

我不想安装VLC，如何使用iTunes完成类似的工作？

在Automator应用中，创建一个新的快速操作。选择“工作流接收当前”项目的“文件夹”选项，然后选择Finder应用程序作为运行该服务的应用程序的选择。

接下来，将AppleScript操作添加到您的工作流程中，然后将以下AppleScript代码插入该新操作中。

property nameExtensions : {"mp3", "wav", "aiff", "m4a"}
on run {input, parameters}
    set thisFolder to input as string
    set newPlaylist to {}

    tell application "System Events"
        set theseFiles to every file of folder thisFolder
        set folderName to name of folder thisFolder
    end tell

    repeat with i from 1 to the count of theseFiles
        set thisFile to item i of theseFiles
        tell application "System Events"
            if name extension of thisFile is in nameExtensions then
                set thisFile to thisFile as alias
                set end of newPlaylist to thisFile
            end if
        end tell
    end repeat

    tell application "iTunes"
        set newPlaylist1 to make new playlist with properties {name:folderName}
        add newPlaylist to newPlaylist1
        play newPlaylist1
    end tell
end run

您可以立即保存Automator文件，并将其命名为“在iTunes中播放”

现在您需要做的就是右键单击包含要在iTunes中播放的音频文件的任何文件夹，然后选择菜单项“快速操作” /“在iTunes中播放”

这将在iTunes中使用包含音频文件的文件夹的名称创建一个新的播放列表，并将立即开始播放该播放列表。

如果您不希望该播放列表成为永久播放列表，并且想在听完文件后删除这些文件，这听起来像是一个不错的小项目，可以通过添加一个额外的代码来帮助您。

附带说明，您可能需要在AppleScript代码的第一行中添加更多音频文件格式。

无论如何，我认为这对您来说都是一个很好的起点