如何在Python中转置函数的两个参数？

如何在调用Python函数时交换两个参数？

如果我point在这两个参数之间加上空格：

self.assertEqual(json.loads(some.data), json_data)

然后M-t（transpose-words），我得到：

self.assertEqual(json.loads(some.json), data_data)

另一方面，使用CMt（transpose-sexps），我得到：

self.assertEqual(json.loadsjson_data, (some.data))

我想要的是：

self.assertEqual(json_data, json.loads(some.data))

有命令可以做到这一点吗？

这也是我很长时间以来一直希望拥有的东西，在这里，我找到了一些动力去做。它可能不是很健壮，但是在第一次尝试时，它似乎涵盖了我尝试过的情况：

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

我使用一种变体transpose-sexps来查找您描述和转置按逗号分隔的情况的情况，或者只是进行常规的情况transpose-sexps。它还将光标留在原处，而不是将其向前拖动，这有点不同，但我个人很喜欢。

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

在使用SMIE的模式下，transpose-sexp在这种情况下应该可以正常工作。当中缀符号（也称为“分隔符”）不是,（或;）而是一个词（例如and）时，它们仍然会失败。

因此，我认为命令是transpose-sexp正确的，并且当此命令无法正常运行时，我将其视为一个错误（但该错误可能很难实现和/或需要花费时间进行修复且优先级较低，因此请不要这样做）屏住呼吸）。解决此问题的方法是设置forward-sexp-function一个函数，该函数将知道“在看到逗号后，我会跳过整个参数”。