在引号内突出显示外壳变量

在vim中，以下文档将使第$PWD2行和第3行以两种不同的方式着色：

#/bin/sh
echo "Current Directory: $PWD"
echo 'Current Directory: $PWD'

的第一个实例$PWD将与它所在的字符串的其余部分具有不同的颜色。这清楚地表明变量将被扩展，而不是被视为原义文本。相比之下，的第二个实例的$PWD颜色将与字符串的其余部分相同，因为单引号会将其视为文字文本。

是否有现有的emacs模式提供这种类型的“ shell引用意识”？

下面的代码使用带有函数的字体锁定规则而不是regexp，该函数$VAR仅在出现在双引号字符串内时才搜索的出现。该函数(syntax-ppss)用于确定这一点。

字体锁定规则使用该prepend标志将其自身添加到现有字符串突出显示的顶部。（请注意，许多程序包都t为此使用。不幸的是，这会覆盖现有突出显示的所有方面。例如，使用时prepend将保留字符串背景色（如果有），同时替换前景色。）

(defun sh-script-extra-font-lock-is-in-double-quoted-string ()
  "Non-nil if point in inside a double-quoted string."
  (let ((state (syntax-ppss)))
    (eq (nth 3 state) ?\")))

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res
                   (re-search-forward
                    "\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\)"
                    limit t))
             (not (sh-script-extra-font-lock-is-in-double-quoted-string))))
    res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode
      (with-no-warnings
        (font-lock-fontify-buffer)))))

您可以通过将最后一个函数添加到合适的钩子来调用use，例如：

(add-hook 'sh-mode-hook 'sh-script-extra-font-lock-activate)

我通过以下方式改进了@Lindydancer的答案：

• 内联sh-script-extra-font-lock-is-in-double-quoted-string函数，因为它仅使用一次
• 转义变量有效。
• 数字变量（$10，$1等）突出显示。

破解代码

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res (progn (if (eq (get-byte) ?$) (backward-char))
                              (re-search-forward
                               "[^\\]\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\|[[:digit:]]+\\)"
                               limit t)))
             (not (eq (nth 3 (syntax-ppss)) ?\")))) res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode (with-no-warnings (font-lock-fontify-buffer)))))