Emacs函数将任意ORG属性转换为任意字符串（即LaTeX标签）吗？

我有许多文档作为具有CUSTOM_LABEL属性的组织文件，例如

* Introduction :PROPERTIES: :CUSTOM_LABEL: AP 1 :END:

在这种情况下，需要将文件导出为LaTeX，并将每个文件翻译CUSTOM_LABEL为\label{marker}。上面的示例应转换为\label{AP 1}。

我已经知道如何在导出时调用自定义函数，但是我不够熟练，无法编写defun来执行该特定转换，即CUSTOM_LABEL->\label{}

如何能在defun函数中注入custom_label作为\label{}写？

我什至只喜欢一些伪代码或一些指针。

我在这里而不是在其他地方问这个问题，因为这是一个Emacs问题，因为我彻底搜索了组织模式手册，并且该功能目前不可用。

在导出时转换特定属性（LaTeX，HTML或任何其他格式）的通用函数会更好。

谢谢。

我编写了一个函数，该函数以相当可扩展的方式满足您的需求。它检查哪些标题包含该属性CUSTOM_LABEL （或您配置的某些其他属性）endless/insert-org-label-latex，并使用属性的值作为参数在每个标题上调用该函数 。

示例代码段还显示了如何将其扩展为html或其他后端。

配置替换

使用此变量，可以配置您关心的属性，以及调用哪些函数来处理每个属性。

(defcustom endless/org-property-mapping 
  '((latex ("CUSTOM_LABEL" . endless/insert-org-label-latex))
    (html ("CUSTOM_LABEL" . endless/insert-org-label-html)))
  "List of mappings from org property to arbitrary strings.
Each element is a list:
  (BACKEND (PROPERTY1 . FUNCTION1) (PROPERTY2 . FUNCTION2) ...)

FUNCTION are functions which get called with a single
argument (the value of PROPERTY) and are responsible for doing
whatever should be done."
  :type '(repeat (cons symbol (repeat (cons string string)))))

重型工人

此功能是您应添加到组织导出挂钩中的功能。它负责检查上面列出的属性，并调用与这些属性关联的函数。

(defun endless/replace-org-property (backend)
  "Convert org properties using `endless/org-property-mapping'.
Lookup BACKEND in `endless/org-property-mapping' for a list of
\(PROPERTY REPLACEMENT). For each healine being exported, if it has a
PROPERTY listed insert a string immediately after the healine given by
    (format REPLACEMENT PROPERTY-VALUE)"
  (let ((map (cdr (assoc backend endless/org-property-mapping)))
        value replacement)
    (when map      
      (org-map-entries
       (lambda () 
         (dolist (it map)
           (save-excursion
             (when (setq value (org-entry-get (point) (car it))) 
               (funcall (cdr it) value)))))))))

(add-hook 'org-export-before-processing-hook #'endless/replace-org-property)

您定义的功能

这些是进行实际替换的。以下是乳胶盒的示例。

(defun endless/insert-org-label-latex (label)
  "Insert \"\\\\label{LABEL}\\n\" after the :PROPERTY: drawer."
  (search-forward-regexp org-property-end-re)
  (forward-char 1)
  (insert (format "\\label{%s}\n" label)))

结果

评估上面的所有代码，然后将以下组织缓冲区导出到Latex。

* Test
  :PROPERTIES:
  :CUSTOM_LABEL: hi
  :END:
Test

生成的乳胶缓冲区应该是这样的。

\section{Test}
\label{sec-1}
\label{hi}
Test

请注意，对于代码片段，您必须使用当前的开发版本(org-version) => "8.3beta"。

请使用CUSTOM_ID和内部链接。请参阅(info "(org) Handling links")。

在大多数情况下，您不必担心Org​​内部命名的导出结果。例如，指向图形和标题的链接在导出时将是正确的。请参阅(info "(org) Internal links")。

对于LaTeX，请尝试：

(with-temp-buffer
  (let ((org-latex-prefer-user-labels t))
(insert "
* h
:PROPERTIES:
:CUSTOM_ID: h
:END:")
(org-mode)
(org-latex-export-as-latex nil nil nil t)))

结果：

\section{h}
\label{h}

在出口商中，例如ox-odt和ox-html标题都包含内部ID ID和CUSTOM_ID。使用哪个链接取决于链接：

(with-temp-buffer
  (let ((org-export-with-toc nil))
(insert "
* h
:PROPERTIES:
:CUSTOM_ID: h
:END:
[[*h]] [[#h]]")
(org-mode)
(org-html-export-as-html nil nil nil t)))

结果：

<div id="outline-container-h" class="outline-2">
<h2 id="h"><a id="sec-1"></a><span class="section-number-2">1</span> h</h2>
<div class="outline-text-2" id="text-h">
<p>
<a href="#sec-1">1</a> <a href="#h">1</a>
</p>
</div>
</div>

我不确定，但是您可能需要建议甚至覆盖导出器功能。在组织8中，即org-latex-export-headline。

该函数获取标题元素，标题内容和其他属性列表。在导出器函数中，您可以使用来获取元素属性（包括自定义标签）org-element-property。