填充段标记文件已更改，即使它没有执行任何操作

每当我调用时fill-paragraph，即使该命令无效（即该段落已被填充），该缓冲区也始终被标记为已修改。它还会创建一个空的可撤消操作（很容易通过检测到undo-tree-mode）。其他有可能进行更改的命令（例如缩进命令）不会将缓冲区标记为已修改，也不会在未进行任何更改的情况下创建可撤消的操作。有什么方法可以使fill-paragraph标记标记为已修改的缓冲区，并仅在实际上更改了某些内容时创建可撤消的操作？

请注意，这对于较新的Emacsen（v.26以上）是固定的。

问题在于fill-paragraph（或更确切地说，fill-region-as-paragraph）会在细分您的段落时删除并重新插入换行符。如果只有一行，它将不会修改缓冲区。您看到的撤消列表中的禁止操作只是fill-paragraph删除并重新插入换行符。

避免这种情况并非易事。以下是一个非常糟糕的技巧，对于大型缓冲区而言效率很低，但也许对您有用。该命令模仿fill-paragraph（M-q）的行为相同，除了在调用之前先存储缓冲区的内容外，此后，如果内容保持不变，它将恢复更改前的修改状态和撤消列表。为此，它需要一个缓冲区内容的副本（实际上是两个），因此，实际上效率很低。:-)

(defun my/fill-paragraph (&optional justify region)
  (interactive (progn
                 (barf-if-buffer-read-only)
                 (list (if current-prefix-arg 'full) t)))
  (let ((old-text (buffer-string))
        (old-modified (buffer-modified-p))
        (old-undo-list buffer-undo-list))
    (fill-paragraph justify region)
    (when (equal old-text (buffer-string))
      (setq buffer-undo-list old-undo-list)
      (set-buffer-modified-p old-modified))))

您可以将其绑定到M-q。

较晚的答案，但这是一个简单的版本，如果文本不变，该版本不会修改缓冲区。

(defun my-fill-paragraph (&optional justify region)
  "Fill paragraph, but don't modify the buffer if filling doesn't
change the text.  See `fill-paragraph' for details."
  (interactive (progn
                 (barf-if-buffer-read-only)
                 (list (if current-prefix-arg 'full) t)))
  (if (buffer-modified-p)
      ;; if modified: use standard fill-paragraph
      (fill-paragraph justify region)
    ;; if unmodified: get a candidate filled version
    (save-excursion
      (let* ((col fill-column)
             (beg (progn (forward-paragraph -1)
                         (skip-syntax-forward " >")
                         (point)))
             (end (progn (forward-paragraph 1)
                         (skip-syntax-backward " >")
                         (point)))
             (old (buffer-substring-no-properties beg end))
             (new (with-temp-buffer
                    (setq fill-column col)
                    (insert old)
                    (fill-paragraph justify region)
                    (buffer-string))))
        ;; don't modify unless the old and new versions differ
        (unless (string-equal old new)
          (delete-region beg end)
          (insert new))))))

它改编了@JorgenSchäfer的答案中的一些想法，但仅适用于当前段落，并且仅以简单的，空格分隔的方式起作用（请参阅有关@JorgenSchäfer的有关引擎盖下并发症的评论）。

这是唯一与我的目的相关的用例（即与“正常”散文互动使用，没有活动区域），所以我要发布它，以防有人想使用它或针对更复杂的用例进行改进。