如何在elisp中设置标记并进行班次选择？

Emacs在瞬态标记模式处于活动状态时的正常行为是，当您进行换档选择时，如果下一个命令是非换档运动，则会取消激活该标记。例如，在命令M-l（用下面的功能标记当前行）和之后C-f，该标记被禁用。之后如何模仿elisp的行为(set-mark-command nil)？

例如：

(defun my-mark-current-line ()
  (interactive)
  (beginning-of-line)
  (set-mark-command nil)
  (end-of-line)
  (forward-char))

(global-set-key (kbd "M-l") 'my-mark-current-line)

现在做M1 Cf，区域将增长，但是，我希望使用默认行为，即在Cf时停用区域，并随CSf一起增长。

编辑：应该使用与set-mark-command不同的功能来允许此操作吗？我找不到。

由于移位转换和标记的临时激活是由命令循环处理的，因此您将需要调用移动功能的交互式版本，以便从它们中获取适当的移位选择行为：

;; (source: http://emacs.stackexchange.com/a/22166/93)
(defun my-mark-current-line ()
  (interactive)
  (beginning-of-line)
  (setq this-command-keys-shift-translated t)
  (call-interactively 'end-of-line)
  (call-interactively 'forward-char))

(global-set-key (kbd "M-l") 'my-mark-current-line)

更新：

自编写上述答案以来，我花了一些时间来了解有关换挡选择真正如何工作的更多信息。它将的符号值设置transient-mark-mode为形式的cons单元(only . OLDVAL)，其中OLDVAL是移位选择之前的值。

下面的解决方案call-interactively通过根据需要激活标记并设置的适当值来避免使用transient-mark-mode。基本上，我认为此解决方案比第一个解决方案要小。

作为奖励，它现在具有可选的重复计数，并且如果标记已处于活动状态，它将在任一方向上扩展当前选择。

;; (source: http://emacs.stackexchange.com/a/22166/93)
(defun my-mark-current-line (&optional arg)
  "Uses shift selection to select the current line.
When there is an existing shift selection, extends the selection
in the appropriate direction to include current line."
  (interactive "p")
  (let ((oldval (or (cdr-safe transient-mark-mode) transient-mark-mode))
        (backwards (and mark-active (> (mark) (point))))
        (beg (and mark-active (mark-marker))))
    (unless beg
      (if backwards (end-of-line) (beginning-of-line))
      (setq beg (point-marker)))
    (if backwards (end-of-line (- 1 arg)) (beginning-of-line (+ 1 arg)))
    (unless mark-active
      (push-mark beg nil t))
    (setq transient-mark-mode (cons 'only oldval))))