如何强制重新评估defvar？

假设我有一个Emacs lisp缓冲区，其中包含：

(defvar foo 1)

如果我调用eval-last-sexp或eval-buffer，foo则绑定到1。如果我将其编辑为：

(defvar foo 2)

eval-last-sexp并且eval-buffer不要重新执行这一行，所以foo还是1。

当存在多个这样的语句并且我必须跟踪哪些行没有被重新评估时，这尤其具有挑战性。

我只看过重新启动Emacs的情况，然后(require 'foo)，但是我必须小心避免加载任何旧的.elc文件。

我如何才能绝对肯定地确保当前文件中定义的变量和函数处于与在新的Emacs实例中重新加载代码相同的状态？

如其他答案所述，使用评估defvar表单eval-last-sexp不会重置默认值。

相反，你可以使用eval-defun（绑定到C-M-x在emacs-lisp-mode默认情况下），它实现了你想作为一个特殊的例外的行为：

如果当前defun实际上是对defvar或的调用，则以defcustom这种方式评估它会使用其初始值表达式重置变量，即使该变量已经具有其他值。（通常defvar，defcustom如果已经存在，则不要更改该值。）

如果您需要评估缓冲区的全部内容，则可以编写一个函数，该函数依次遍历顶级表单并对其进行调用eval-defun。这样的事情应该起作用：

(defun my/eval-buffer ()
  "Execute the current buffer as Lisp code.
Top-level forms are evaluated with `eval-defun' so that `defvar'
and `defcustom' forms reset their default values."
  (interactive)
  (save-excursion
    (goto-char (point-min))
    (while (not (eobp))
      (forward-sexp)
      (eval-defun nil))))

就像其他答案说的那样，这只是defvar的工作方式，但是您可以绕开它，毕竟这是elisp。

您可以临时重新定义defvar的工作方式，并在此期间重新加载要重置的软件包。

我写了一个宏，其中在评估身体时，将始终重新评估defvars值。

(defmacro my-fake-defvar (name value &rest _)
  "defvar impersonator that forces reeval."
  `(progn (setq ,name ,value)
          ',name))

(defmacro with-forced-defvar-eval (&rest body)
  "While evaluating, any defvars encountered are reevaluated"
  (declare (indent defun))
  (let ((dv-sym (make-symbol "old-defvar")))
    `(let ((,dv-sym (symbol-function 'defvar)))
       (unwind-protect
           (progn
             (fset 'defvar (symbol-function 'my-fake-defvar))
             ,@body)
         (fset 'defvar ,dv-sym)))))

用法示例：

file_a.el

(defvar my-var 10)

file_b.el

(with-forced-defvar-eval
  (load-file "file_a.el")
  (assert (= my-var 10))
  (setq my-var 11)
  (assert (= my-var 11)
  (load-file "file_a.el")
  (assert (= my-var 10))

注意：这仅应用于重新评估defvar，因为重新评估时它仅忽略文档字符串。您可以修改宏以支持重新评估也适用于文档字符串，但是我将由您自己决定。

在你的情况下你可以做

(with-forced-defvar-eval (require 'some-package))

但是知道那些编写elisp的人这样做是希望defvar能够按指定方式工作，这可能是因为他们使用defvar来定义，并在某个init函数中使用setq来指定值，所以您可能最终会放弃不想要的变量，但是这可能很少见。

替代实施

使用此方法，您可以全局重新定义defvar，并控制是否通过更改新defvar-always-reeval-values符号的值来定义符号的值是否设置为INIT-VALUE arg 。

;; save the original defvar definition
(fset 'original-defvar (symbol-function 'defvar))

(defvar defvar-always-reeval-values nil
  "When non-nil, defvar will reevaluate the init-val arg even if the symbol is defined.")

(defmacro my-new-defvar (name &optional init-value docstring)
  "Like defvar, but when `defvar-always-reeval-values' is non-nil, it will set the symbol's value to INIT-VALUE even if the symbol is defined."
  `(progn
     (when defvar-always-reeval-values (makunbound ',name))
     (original-defvar ,name ,init-value ,docstring)))

;; globally redefine defvar to the new form
(fset 'defvar (symbol-function 'my-new-defvar))

将defvar被评估，做你指定什么。但是，defvar仅设置一个初始值：

仅当SYMBOL的值为void时，才对可选参数INITVALUE进行评估，并用于设置SYMBOL。

因此，要实现您想要的目标，您将需要在重新评估之前取消绑定变量，例如

(makunbound 'foo)

或用于setq设置值，例如

(defvar foo nil "My foo variable.")
(setq foo 1)

如果您不需要在此处指定文档字符串，则可以defvar完全跳过。

如果您确实要使用defvar并自动取消绑定，则需要编写一个函数以defvar在当前缓冲区（或区域，或最后的sexp等）中查找调用；呼吁makunbound每个；然后进行实际评估。

通过跟踪宏eval-defun的支持功能并对其进行修改，可以创建以下宏，从而不再需要评估特定缓冲区的区域。我需要相关线程中的帮助，将表达式转换为字符串，然后@Tobias进行了急救-教我如何将不完美的函数转换为宏。我认为我们不必eval-sexp-add-defvars先行elisp--eval-defun-1，但是如果有人认为这很重要，请告诉我。

;;; EXAMPLE:
;;;   (defvar-reevaluate
;;;     (defvar undo-auto--this-command-amalgamating "hello-world"
;;;     "My new doc-string."))

(defmacro defvar-reevaluate (input)
"Force reevaluation of defvar."
  (let* ((string (prin1-to-string input))
        (form (read string))
        (form (elisp--eval-defun-1 (macroexpand form))))
    form))

问题不在于该生产线没有得到重新评估。问题是defvar定义了一个变量及其默认值。如果变量已经存在，则更改其默认值不会修改当前值。不幸的是，我认为您将需要setq为每个要更新其值的变量运行a 。

这可能有点过分，但是如果您希望能够轻松更新foo到其新的默认值，则可以像这样更新文件。

(defvar foo 2)
(setq foo 2)

但这要求您在代码中的两个位置维护默认值。您也可以这样做：

(makunbound 'foo)
(defvar foo 2)

但是如果有在foo其他地方声明的机会，您可能会遇到一些副作用。