类似于搜索/替换的功能，用于交换文本

我经常发现自己试图取代如foo与bar和bar与foo在缓冲区中。

我通常的方式是：

• 3查询-替换：aaa -> @@@，bbb -> aaa，@@@ -> bbb
• 放弃自动化，只需要手工更换

我想可以使用,语法query-replace-regexp来测试匹配的字符串是否为aaa或bbb。但是产生的语法太麻烦了，所以我从来没有真正尝试过。

问题是，考虑到任务的普遍性，我认为必须有更好的单步执行方式，无论是内置的还是现有的程序包。在那儿？

这是一个小命令，它将执行此操作：

(defun query-swap-strings (from-string to-string &optional delimited start end)
  "Swap occurrences of FROM-STRING and TO-STRING."
  (interactive
   (let ((common
          (query-replace-read-args
           (concat "Query swap"
                   (if current-prefix-arg
                       (if (eq current-prefix-arg '-) " backward" " word")
                     "")
                   (if (use-region-p) " in region" ""))
           nil)))
     (list (nth 0 common) (nth 1 common) (nth 2 common)
           (if (use-region-p) (region-beginning))
           (if (use-region-p) (region-end)))))
  (perform-replace
   (concat "\\(" (regexp-quote from-string) "\\)\\|" (regexp-quote to-string))
   `(replace-eval-replacement replace-quote (if (match-string 1) ,to-string ,from-string))
   t t delimited nil nil start end))

安装plur

并运行命令 plur-query-replace

和输入{foo,bar}及其替换{bar,foo}

点击y以替换所需的出现。

此命令也有非交互式且类似于isearch的变体。