根据主题设置组织导出的<code>块的背景

我经常导出组织模式文件，并且几乎所有文件中都有代码。当我导出代码时，最终会根据主题为文本着色，但是，我会定期在深色主题和浅色主题之间切换。对于浅色主题，这些<code>块需要具有浅色背景，对于深色主题，它们需要具有深色背景（否则，我最终在浅灰色背景上显示浅黄色文本，这是不可读的）。

我必须为深色背景添加此行：

#+HTML_HEAD: <style>pre.src {background-color: #303030; color: #e5e5e5;}</style>

然后记得在我切换到浅色背景时将其删除

有没有一种方法可以在导出时自动检测当前主题的背景色，并将其用于导出的HTML的CSS中？

编辑

我使用Jordon的答案（感谢Jordon，您得到了业障积分！），但是我想发布最终添加到我的代码中的解决方案，因为它是他的答案的稍微修改后的版本：

(defun my/org-inline-css-hook (exporter)
  "Insert custom inline css to automatically set the
background of code to whatever theme I'm using's background"
  (when (eq exporter 'html)
    (let* ((my-pre-bg (face-background 'default))
           (my-pre-fg (face-foreground 'default)))
      (setq
       org-html-head-extra
       (concat
        org-html-head-extra
        (format "<style type=\"text/css\">\n pre.src {background-color: %s; color: %s;}</style>\n"
                my-pre-bg my-pre-fg))))))

(add-hook 'org-export-before-processing-hook 'my/org-inline-css-hook)

这不仅设置了背景色，还设置了前景色。还将行添加到现有org-html-head-extra设置，这样就不会意外覆盖其他HTML。我已经测试过，这对我非常有用！

首先，我相信org可以htmlize根据您的主题自动为您的源代码块着色。

或者。

查看http://definitelyaplug.b0.cx/post/custom-inlined-css-in-org-mode-html-export/。它有一个很好的示例，说明了如何org-export-before-processing-hook在HTML导出之前使用来将自定义CSS扔到组织文档上。

如果站点关闭，下面是代码：

在html导出的此处，org将在当前目录中查找名为styles.css的文件，或在.emacs.d目录中查找默认文件，然后将该CSS注入文档中。这很好，但对于您的用例而言并不完美。

(defun my-org-inline-css-hook (exporter)
  "Insert custom inline css"
  (when (eq exporter 'html)
    (let* ((dir (ignore-errors (file-name-directory (buffer-file-name))))
           (path (concat dir "style.css"))
           (homestyle (or (null dir) (null (file-exists-p path))))
           (final (if homestyle "~/.emacs.d/org-style.css" path)))
      (setq org-html-head-include-default-style nil)
      (setq org-html-head (concat
                           "<style type=\"text/css\">\n"
                           "<!--/*--><![CDATA[/*><!--*/\n"
                           (with-temp-buffer
                             (insert-file-contents final)
                             (buffer-string))
                           "/*]]>*/-->\n"
                           "</style>\n")))))

(add-hook 'org-export-before-processing-hook 'my-org-inline-css-hook)

您可以通过几种方式对其进行自定义，以使其按您希望的方式工作。

一种方法是根据您的主题手动构建css并将其插入。

这是修改后的版本，将的背景设置pre.src为默认faces：background属性的十六进制值。

(defun my-org-inline-css-hook (exporter)
  "Insert custom inline css"
  (when (eq exporter 'html)
    (let ((my-pre-bg (face-background 'default)))
      (setq org-html-head-include-default-style nil)
      (setq org-html-head
            (format "<style type=\"text/css\">\n pre.src { background-color: %s;}</style>\n" my-pre-bg)))))

(add-hook 'org-export-before-processing-hook 'my-org-inline-css-hook)