在大型缓冲区中获取“行中行号”的更快方法

line-number-at-pos当点接近缓冲区的末端时，该函数（当重复约50次时）会导致半大缓冲区（例如50,000条线）明显减速。减速是指总计约1.35秒。

与其使用100％的elisp函数对行进行计数并转到缓冲区的顶部，我对一种混合方法感兴趣，该方法利用了负责出现在模式行上的行号的内置C功能。不管缓冲区的大小如何，出现在模式行上的行号都会以光速出现。

这是一个测试功能：

(defmacro measure-time (&rest body)
"Measure the time it takes to evaluate BODY.
http://lists.gnu.org/archive/html/help-gnu-emacs/2008-06/msg00087.html"
  `(let ((time (current-time)))
     ,@body
     (message "%.06f" (float-time (time-since time)))))

(measure-time
  (let* (
      line-numbers
      (window-start (window-start))
      (window-end (window-end)))
    (save-excursion
      (goto-char window-end)
      (while
        (re-search-backward "\n" window-start t)
        (push (line-number-at-pos) line-numbers)))
    line-numbers))

尝试

(string-to-number (format-mode-line "%l"))

您可以使用《 Emacs Lisp手册》中描述的％-Constructs提取其他信息。

警告：

除了wasamasa 和Stefan指出的限制（请参阅下面的注释），这对于未显示的缓冲区不起作用。

尝试这个：

(with-temp-buffer
  (dotimes (i 10000)
    (insert (format "%d\n" i)))
  (string-to-number (format-mode-line "%l")))

并比较

(with-temp-buffer
  (dotimes (i 10000)
    (insert (format "%d\n" i)))
  (line-number-at-pos))

nlinum.el使用以下内容：

(defvar nlinum--line-number-cache nil)
(make-variable-buffer-local 'nlinum--line-number-cache)

;; We could try and avoid flushing the cache at every change, e.g. with:
;;   (defun nlinum--before-change (start _end)
;;     (if (and nlinum--line-number-cache
;;              (< start (car nlinum--line-number-cache)))
;;         (save-excursion (goto-char start) (nlinum--line-number-at-pos))))
;; But it's far from clear that it's worth the trouble.  The current simplistic
;; approach seems to be good enough in practice.

(defun nlinum--after-change (&rest _args)
  (setq nlinum--line-number-cache nil))

(defun nlinum--line-number-at-pos ()
  "Like `line-number-at-pos' but sped up with a cache."
  ;; (assert (bolp))
  (let ((pos
         (if (and nlinum--line-number-cache
                  (> (- (point) (point-min))
                     (abs (- (point) (car nlinum--line-number-cache)))))
             (funcall (if (> (point) (car nlinum--line-number-cache))
                          #'+ #'-)
                      (cdr nlinum--line-number-cache)
                      (count-lines (point) (car nlinum--line-number-cache)))
           (line-number-at-pos))))
    ;;(assert (= pos (line-number-at-pos)))
    (setq nlinum--line-number-cache (cons (point) pos))
    pos))

在mode函数中使用以下额外配置：

(add-hook 'after-change-functions #'nlinum--after-change nil t)