每行一句编辑文件

有点背景。

我正在尝试对乳胶文档进行版本控制，如果我采用每行一句的方法，该计划的有效性将会大大提高。

例如，以下是我的文档的外观。

Some text here.
New stencence on the same paragraph.
Some more text, still on the same paragraph.

This is another paragraph.

我的问题很简单。
我可以使用Emacs自动化/改善其中的多少？

以下是我要记住的两点。

1. 我的句子很长，因此我需要换行而不实际填充它们。也就是说，一个很长的句子需要在我的屏幕上显示在多行上，但是在“ .tex”文件中必须是一行。最好以不包裹方程式的方式来完成。

   visual-line-mode以窗口宽度包装，该宽度太宽。我需要包装线并将行的宽度限制为80个左右的字符。就像fill-paragraph通常那样，但实际上不会破坏文件中的行。

2. 我可以在每个句子后面手动换行，但是如果我可以配置fill-paragraph（甚至可以auto-fill-mode）在每行放置一个句子，那将是非常可取的。

如果您只想要类似visual-line-mode但可配置的内容，则可以尝试一下longlines-mode，这是我大部分散文所使用的。longlines-mode包裹您的文本，类似于visual-line-mode使用所配置的宽度fill-column。

这是fill-column设置为的屏幕截图70（该窗口实际上向右延伸得更多）。

配置fill-paragraph会很整洁，但是我不确定该怎么做。取而代之的是，这是一个合理的临时技巧：.在TeX模式下使角色变为电动，并插入换行符。这仅涉及以任何适当的模式挂钩重新绑定它：

(defun my-electric-dot ()
  (interactive)
  (insert ".\n"))
(defun my-tex-hook ()
  (local-set-key (kbd ".") 'my-electric-dot))
(add-hook 'TeX-mode-hook 'my-tex-hook)

对于（1），我将使用扩大的边距，以便visual-line-mode将行换成所需的fill-column。但是，这将影响文本行和方程式。

至于（2），可以定义一个自定义的填充命令来绑定M-q并正确填充段落。我尚未设法编写出具有自动填充正确行为的命令。

在次要模式下包装所有内容，如下所示。它不是很漂亮的代码，但是在大多数情况下应该可以使用。（我已经unfill-paragraph在init.el相当长的一段时间内使用了该功能，而没有注意到问题）。

(define-minor-mode ospl-mode
  "One Sentence Per Line"
  :init-value nil
  :lighter " ospl"
  :keymap (let ((map (make-sparse-keymap)))
            (define-key map (kbd "M-q") 'ospl/fill-paragraph)
            map)

  (if ospl-mode
      (progn
        (visual-line-mode 1)
        (setq right-margin-width (- (window-body-width) fill-column)))
    (visual-line-mode -1)
    (setq right-margin-width 0))

  ;; Account for new margin width
  (set-window-buffer (selected-window) (current-buffer)))


(defun ospl/unfill-paragraph ()
  "Unfill the paragraph at point.

This repeatedly calls `join-line' until the whole paragraph does
not contain hard line breaks any more."
  (interactive)
  (forward-paragraph 1)
  (forward-paragraph -1)
  (while (looking-at paragraph-start)
    (forward-line 1))
  (let ((beg (point)))
    (forward-paragraph 1)
    (backward-char 1)
    (while (> (point) beg)
      (join-line)
      (beginning-of-line))))


(defun ospl/fill-paragraph ()
  "Fill the current paragraph until there is one sentence per line.

This unfills the paragraph, and places hard line breaks after each sentence."
  (interactive)
  (save-excursion
    (fill-paragraph)         ; takes care of putting 2 spaces if needed
    (ospl/unfill-paragraph)  ; remove hard line breaks

    ;; insert line breaks again
    (let ((end-of-paragraph (make-marker)))
      (save-excursion
        (forward-paragraph)
        (backward-sentence)
        (forward-sentence)
        (set-marker end-of-paragraph (point)))
      (forward-sentence) 
      (while (< (point) end-of-paragraph)
        (just-one-space)
        (delete-backward-char 1)
        (newline)
        (forward-sentence))
      (set-marker end-of-paragraph nil)))) 

如果使用git diff --color-words或latexdiff，是否可以避免/解决版本控制问题？然后，您可以查看更改的单词。

一种改进（我有时使用）的方法是，通过使用AUCTeX的一部分来折叠换行符，将换行符显示为彼此tex-fold连续的句子。

这意味着

Lorem ipsum dolor sit amet, consectetur adipiscing elit.
Mauris pellentesque fringilla justo, quis dapibus velit tincidunt quis?
Quisque varius ligula arcu, ut imperdiet risus maximus nec.

折叠到

Lorem ipsum dolor sit amet, consectetur adipiscing elit⁎ Mauris pellentesque fringilla justo, quis dapibus velit tincidunt quis❓  Quisque varius ligula arcu, ut imperdiet risus maximus nec⁎

我最近将其作为次要模式放在了一个包中。也许其他人也会发现这个有用：https : //github.com/andersjohansson/tex-fold-linebreaks