使用AUCTeX自动缩进\ if语句

涉及if -like语句的AUCTeX原始tex代码的当前行为是在与周围条件相同的级别上缩进条件语句。即代码如

\if@sometoggle%
\dosomething%
\else%
\doanotherthing%
\fi%

显示为一大段文字。我想使AUCTeX代码段缩进如下：

\if@sometoggle%
  \dosomething%
\else%
  \doanotherthing%
\fi%

这可能吗？

这是可能的：

(setq LaTeX-begin-regexp "\\(?:begin\\|if@\\)\\b")
(setq LaTeX-end-regexp "\\(?:end\\|else\\|fi\\)\\b")
(defun LaTeX-indent-level-count ()
  "Count indentation change caused by all \\left, \\right, \\begin, and
\\end commands in the current line."
  (save-excursion
    (save-restriction
      (let ((count 0))
        (narrow-to-region (point)
                          (save-excursion
                            (re-search-forward
                             (concat "[^" TeX-esc "]"
                                     "\\(" LaTeX-indent-comment-start-regexp
                                     "\\)\\|\n\\|\\'"))
                            (backward-char)
                            (point)))
        (while (search-forward TeX-esc nil t)
          (cond
            ((looking-at "left\\b")
             (setq count (+ count LaTeX-left-right-indent-level)))
            ((looking-at "right\\b")
             (setq count (- count LaTeX-left-right-indent-level)))
            ((looking-at LaTeX-begin-regexp)
             (setq count (+ count LaTeX-indent-level)))
            ((looking-at "else\\b"))
            ((looking-at LaTeX-end-regexp)
             (setq count (- count LaTeX-indent-level)))
            ((looking-at (regexp-quote TeX-esc))
             (forward-char 1))))
        count))))

请注意，我必须重新定义LaTeX-indent-level-count。diff只是一个cond分支：

((looking-at "else\\b"))