org：如何按TODO排序标题，然后按优先级排序？

我经常有这样的清单：

* Main heading
** TODO [#A] Make world better
** TODO [#B] Make Emacs better 
** TODO [#B] Customize emacs 
** DONE [#C] some task
** TODO [#A] Launch rocket to mars

我想首先根据“ TODO”任务字对它进行排序。然后，我想按优先级对已排序的TODO中的项目进行排序。（然后按“工作量”进一步排序将是不错的选择）。

我的意思是，当前我可以单击主标题，并已按优先级或todo关键字对子级进行排序，但不能同时对二者进行排序。

是否可以像排序策略一样进行排序？

目前我有两个标题

* Tasks
** TODO [#A] meh
** TODO [#B] meh2
* Completed.
** DONE [#B] meh3.

但是这种方法的问题在于，当我完成任务时，我不得不不断地拖延任务。

[编辑]
这有点类似于此，除了我无法理解他的回答以将其转移到我的需要上吗？

如果可以使用进行类似操作org-agenda-sorting-stratagy，那就太好了org-sort-entries，但是似乎没有。我们可以伪造它，因为org-sort-entries可以接受一个参数，该参数指定一个为每个标题分配（字符串或数字）键的函数，当?f给出排序类型时，该键将用于对条目进行排序。我们要做的就是获取TODO和PRIORITY属性的字符串。诀窍是我们要按TODO属性在中的位置排序org-todo-keywords，而不是按字母顺序排序。

(require 'cl)
(require 'dash)

(defun todo-to-int (todo)
    (first (-non-nil
            (mapcar (lambda (keywords)
                      (let ((todo-seq
                             (-map (lambda (x) (first (split-string  x "(")))
                                   (rest keywords)))) 
                        (cl-position-if (lambda (x) (string= x todo)) todo-seq)))
                    org-todo-keywords))))

(defun my/org-sort-key ()
  (let* ((todo-max (apply #'max (mapcar #'length org-todo-keywords)))
         (todo (org-entry-get (point) "TODO"))
         (todo-int (if todo (todo-to-int todo) todo-max))
         (priority (org-entry-get (point) "PRIORITY"))
         (priority-int (if priority (string-to-char priority) org-default-priority)))
    (format "%03d %03d" todo-int priority-int)
    ))

(defun my/org-sort-entries ()
  (interactive)
  (org-sort-entries nil ?f #'my/org-sort-key))

M-x my/org-sort-entries将按TODO关键字排序，并与PRIORITY断开联系（org-default-priority在不指定优先级的情况下使用）。如果您有1000个以上的TODO关键字，则此操作会中断，这是不这样做的一个很好的理由。

将以下内容添加到您的文件中：

#+ARCHIVE: :: * Completed.

改组成为存档

与其对条目进行排序，不如对排序视图进行排序？

(setq org-agenda-custom-commands
      '(("cx" "TODOs sorted by state, priority, effort"
         todo "*"
         ((org-agenda-overriding-header "\nTODOs sorted by state, priority, effort")
          (org-agenda-sorting-strategy '(todo-state-down priority-down effort-up))))))

使用将它限制为当前文件<。您可以标记“完成”并从已排序的视图中存档。

您还可以定义一个org-agenda-cmp-user-defined函数并将其添加到中org-agenda-sorting-strategy。这是我创建的一个示例。

(setq org-todo-sort-order '("WAIT" "TODO" "DOING" "CANCELED" "DONE"))

(defun my:user-todo-sort (a b)
  "Sort todo based on which I want to see first"
  (when-let ((state-a (get-text-property 14 'todo-state a))
             (state-b (get-text-property 14 'todo-state b))
             (cmp (--map (cl-position-if (lambda (x)
                                           (equal x it))
                                         org-todo-sort-order)
                         (list state-a state-b))))
    (cond ((apply '> cmp) 1)
          ((apply '< cmp) -1)
          (t nil))))
(setq org-agenda-cmp-user-defined 'my:user-todo-sort)

您可以使用我制作的这个库：https : //github.com/felipelalli/org-sort-tasks

它通过询问用户任务A是否比任务B重要来使用合并排序算法，然后构建排序列表。