选定的答案有效，但可能会有一些改进。
- 这些选项可能应该初始化为默认值。
- 保留％0以及所需的参数％1和％2会很好。
- 为每个选项设置IF块变得很痛苦，尤其是随着选项数量的增加。
- 如果有一种简单明了的方法来在一处快速定义所有选项和默认值，那就太好了。
- 支持充当标志的独立选项会很好（该选项后没有值）。
- 我们不知道arg是否包含在引号中。我们也不知道是否使用转义字符传递了arg值。最好使用％〜1访问arg并将赋值用引号引起来。然后，该批处理可以依靠不带引号引起来，但是特殊字符通常仍然是安全的，无需转义。（这不是防弹的，但可以处理大多数情况）
我的解决方案依赖于OPTIONS变量的创建，该变量定义所有选项及其默认值。选项还用于测试提供的选项是否有效。通过将选项值简单地存储在与选项相同的变量中，可以节省大量代码。无论定义了多少选项，代码量都是恒定的。仅选项定义必须更改。
编辑 -而且，如果强制位置参数的数量更改，则：loop代码必须更改。例如，通常所有参数都被命名，在这种情况下，您想解析从位置1而不是3开始的参数。因此，在：loop中，所有3变为1，而4变为2。
@echo off
setlocal enableDelayedExpansion
:: Define the option names along with default values, using a <space>
:: delimiter between options. I'm using some generic option names, but
:: normally each option would have a meaningful name.
::
:: Each option has the format -name:[default]
::
:: The option names are NOT case sensitive.
::
:: Options that have a default value expect the subsequent command line
:: argument to contain the value. If the option is not provided then the
:: option is set to the default. If the default contains spaces, contains
:: special characters, or starts with a colon, then it should be enclosed
:: within double quotes. The default can be undefined by specifying the
:: default as empty quotes "".
:: NOTE - defaults cannot contain * or ? with this solution.
::
:: Options that are specified without any default value are simply flags
:: that are either defined or undefined. All flags start out undefined by
:: default and become defined if the option is supplied.
::
:: The order of the definitions is not important.
::
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
:: Set the default option values
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
:: Validate and store the options, one at a time, using a loop.
:: Options start at arg 3 in this example. Each SHIFT is done starting at
:: the first option so required args are preserved.
::
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
rem No substitution was made so this is an invalid option.
rem Error handling goes here.
rem I will simply echo an error message.
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
rem Set the flag option using the option name.
rem The value doesn't matter, it just needs to be defined.
set "%~3=1"
) else (
rem Set the option value using the option as the name.
rem and the next arg as the value
set "%~3=%~4"
shift /3
)
shift /3
goto :loop
)
:: Now all supplied options are stored in variables whose names are the
:: option names. Missing options have the default value, or are undefined if
:: there is no default.
:: The required args are still available in %1 and %2 (and %0 is also preserved)
:: For this example I will simply echo all the option values,
:: assuming any variable starting with - is an option.
::
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
确实没有那么多代码。上面的大多数代码是注释。这是完全相同的代码，没有注释。
@echo off
setlocal enableDelayedExpansion
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
set "%~3=1"
) else (
set "%~3=%~4"
shift /3
)
shift /3
goto :loop
)
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
此解决方案在Windows批处理中提供Unix样式参数。这不是Windows的规范-批处理通常在必需的参数之前具有选项，并且该选项带有前缀/。
该解决方案中使用的技术很容易适应Windows风格的选项。
- 解析循环始终在处寻找一个选项
%1，并一直持续到arg 1不以开头/
- 请注意，如果名称以开头，则SET分配必须用引号引起来
/。
SET /VAR=VALUE失败了
SET "/VAR=VALUE"。无论如何，我已经在解决方案中这样做了。
- 标准Windows样式排除了以开头的第一个必需参数值的可能性
/。通过使用隐式定义的//选项作为信号退出选项解析循环，可以消除此限制。//“选项”将不会存储任何内容。
2015年12月28日更新：支持!in选项值
在上面的代码中，在启用延迟扩展的同时扩展了每个参数，这意味着!最有可能剥离了该参数，否则将进行类似!var!的扩展。此外，^如果!存在，也可以剥离。以下对未注释代码的小修改消除了这样的限制，!并将^其保留在选项值中。
@echo off
setlocal enableDelayedExpansion
set "options=-username:/ -option2:"" -option3:"three word default" -flag1: -flag2:"
for %%O in (%options%) do for /f "tokens=1,* delims=:" %%A in ("%%O") do set "%%A=%%~B"
:loop
if not "%~3"=="" (
set "test=!options:*%~3:=! "
if "!test!"=="!options! " (
echo Error: Invalid option %~3
) else if "!test:~0,1!"==" " (
set "%~3=1"
) else (
setlocal disableDelayedExpansion
set "val=%~4"
call :escapeVal
setlocal enableDelayedExpansion
for /f delims^=^ eol^= %%A in ("!val!") do endlocal&endlocal&set "%~3=%%A" !
shift /3
)
shift /3
goto :loop
)
goto :endArgs
:escapeVal
set "val=%val:^=^^%"
set "val=%val:!=^!%"
exit /b
:endArgs
set -
:: To get the value of a single parameter, just remember to include the `-`
echo The value of -username is: !-username!
